---
title: "सुरक्षा उपायांसह ERC-20"
description: "लोकांना मूर्खपणाच्या चुका टाळण्यास कशी मदत करावी"
author: "ओरी पोमेरँट्झ"
lang: mr
tags: ["erc-20"]
skill: beginner
breadcrumb: "ERC-20 सुरक्षा"
published: 2022-08-15
---

## परिचय {#introduction}

इथेरियमची एक उत्तम गोष्ट म्हणजे तुमचे व्यवहार बदलू किंवा रद्द करू शकेल असा कोणताही केंद्रीय प्राधिकरण (central authority) नाही. इथेरियमची एक मोठी समस्या ही आहे की वापरकर्त्यांच्या चुका किंवा बेकायदेशीर व्यवहार रद्द करण्याचा अधिकार असलेल्या कोणत्याही केंद्रीय प्राधिकरणाचा अभाव आहे. या लेखात तुम्ही वापरकर्ते [ERC-20](/developers/docs/standards/tokens/erc-20/) टोकन वापरताना करत असलेल्या काही सामान्य चुकांबद्दल शिकाल, तसेच वापरकर्त्यांना त्या चुका टाळण्यास मदत करणारे किंवा केंद्रीय प्राधिकरणाला काही अधिकार (उदा. खाती गोठवणे) देणारे ERC-20 कॉन्ट्रॅक्ट कसे तयार करावे हे शिकाल.

लक्षात घ्या की आम्ही [ओपनझेपलिन ERC-20 टोकन कॉन्ट्रॅक्ट](https://github.com/OpenZeppelin/openzeppelin-contracts/tree/master/contracts/token/ERC20) वापरणार असलो तरी, हा लेख त्याचे सविस्तर स्पष्टीकरण देत नाही. तुम्ही ही माहिती [येथे](/developers/tutorials/erc20-annotated-code) शोधू शकता.

जर तुम्हाला संपूर्ण सोर्स कोड पाहायचा असेल:

1. [Remix IDE](https://remix.ethereum.org/) उघडा.
2. क्लोन GitHub आयकॉनवर क्लिक करा (![clone github icon](icon-clone.png)).
3. `https://github.com/qbzzt/20220815-erc20-safety-rails` हे GitHub रिपॉझिटरी क्लोन करा.
4. **contracts > erc20-safety-rails.sol** उघडा.

## ERC-20 कॉन्ट्रॅक्ट तयार करणे {#creating-an-erc-20-contract}

सुरक्षा उपायांची कार्यक्षमता जोडण्यापूर्वी आपल्याला ERC-20 कॉन्ट्रॅक्टची आवश्यकता आहे. या लेखात आम्ही [ओपनझेपलिन कॉन्ट्रॅक्ट्स विझार्ड](https://docs.openzeppelin.com/contracts/5.x/wizard) वापरू. ते दुसऱ्या ब्राउझरमध्ये उघडा आणि या सूचनांचे पालन करा:

1. **ERC20** निवडा.
2. या सेटिंग्ज प्रविष्ट करा:

   | पॅरामीटर       | मूल्य            |
   | -------------- | ---------------- |
   | Name           | SafetyRailsToken |
   | Symbol         | SAFE             |
   | Premint        | 1000             |
   | Features       | None             |
   | Access Control | Ownable          |
   | Upgradability  | None             |

3. वर स्क्रोल करा आणि **Open in Remix** (Remix साठी) किंवा वेगळे वातावरण वापरण्यासाठी **Download** वर क्लिक करा. मी असे गृहीत धरत आहे की तुम्ही Remix वापरत आहात, जर तुम्ही दुसरे काही वापरत असाल तर योग्य ते बदल करा.
4. आता आपल्याकडे पूर्णपणे कार्यशील ERC-20 कॉन्ट्रॅक्ट आहे. आयात केलेला कोड पाहण्यासाठी तुम्ही `.deps` > `npm` विस्तृत करू शकता.
5. कॉन्ट्रॅक्ट ERC-20 कॉन्ट्रॅक्ट म्हणून कार्य करते हे पाहण्यासाठी ते संकलित (compile) करा, प्रस्थापित करा आणि त्याच्यासोबत प्रयोग करा. जर तुम्हाला Remix कसे वापरायचे हे शिकायचे असेल, तर [हे ट्युटोरियल वापरा](https://remix.ethereum.org/?#activate=udapp,solidity,LearnEth).

## सामान्य चुका {#common-mistakes}

### चुका {#the-mistakes}

वापरकर्ते कधीकधी चुकीच्या पत्त्यावर टोकन पाठवतात. त्यांना नेमके काय करायचे होते हे जाणून घेण्यासाठी आपण त्यांचे मन वाचू शकत नसलो तरी, दोन प्रकारच्या चुका खूप वेळा घडतात आणि त्या शोधणे सोपे आहे:

1. कॉन्ट्रॅक्टच्या स्वतःच्या पत्त्यावर टोकन पाठवणे. उदाहरणार्थ, [ऑप्टिमिझम् च्या OP टोकनने](https://optimism.mirror.xyz/qvd0WfuLKnePm1Gxb9dpGchPf5uDz5NSMEFdgirDS4c) दोन महिन्यांपेक्षा कमी कालावधीत [120,000 पेक्षा जास्त](https://optimism.blockscout.com/address/0x4200000000000000000000000000000000000042) OP टोकन जमा केले. हे संपत्तीचे एक महत्त्वपूर्ण प्रमाण दर्शवते जे बहुधा लोकांनी गमावले आहे.

2. रिकाम्या पत्त्यावर टोकन पाठवणे, जो [बाह्य मालकीच्या खात्याशी (externally owned account)](/developers/docs/accounts/#externally-owned-accounts-and-key-pairs) किंवा [स्मार्ट कॉन्ट्रॅक्टशी](/developers/docs/smart-contracts) संबंधित नाही. हे किती वेळा घडते याची आकडेवारी माझ्याकडे नसली तरी, [एका घटनेत 20,000,000 टोकन्सचे नुकसान होऊ शकले असते](https://gov.optimism.io/t/message-to-optimism-community-from-wintermute/2595).

### हस्तांतरण रोखणे {#preventing-transfers}

ओपनझेपलिन ERC-20 कॉन्ट्रॅक्टमध्ये [एक हूक, `_beforeTokenTransfer`](https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC20/ERC20.sol#L364-L368) समाविष्ट आहे, जो टोकन हस्तांतरित होण्यापूर्वी कॉल केला जातो. डीफॉल्टनुसार हा हूक काहीही करत नाही, परंतु आपण त्यावर आपली स्वतःची कार्यक्षमता जोडू शकतो, जसे की काही समस्या असल्यास पूर्ववत करणारे (revert) तपासणी (checks).

हा हूक वापरण्यासाठी, कन्स्ट्रक्टर नंतर हे फंक्शन जोडा:

```solidity
    function _beforeTokenTransfer(address from, address to, uint256 amount)
        internal virtual
        override(ERC20)
    {
        super._beforeTokenTransfer(from, to, amount);
    }
```

जर तुम्हाला Solidity ची फारशी माहिती नसेल तर या फंक्शनचे काही भाग नवीन असू शकतात:

```solidity
        internal virtual
```

`virtual` कीवर्डचा अर्थ असा आहे की ज्याप्रमाणे आपण `ERC20` कडून कार्यक्षमता वारशाने मिळवली (inherited) आणि हे फंक्शन ओव्हरराइड केले, त्याचप्रमाणे इतर कॉन्ट्रॅक्ट्स आपल्याकडून वारसा मिळवू शकतात आणि हे फंक्शन ओव्हरराइड करू शकतात.

```solidity
        override(ERC20)
```

आपण `_beforeTokenTransfer` ची ERC20 टोकन व्याख्या [ओव्हरराइड](https://docs.soliditylang.org/en/v0.8.15/contracts.html#function-overriding) करत आहोत हे आपल्याला स्पष्टपणे नमूद करावे लागेल. सर्वसाधारणपणे, सुरक्षिततेच्या दृष्टिकोनातून, अस्पष्ट (implicit) व्याख्यांपेक्षा स्पष्ट (explicit) व्याख्या खूप चांगल्या असतात - जर एखादी गोष्ट तुमच्या समोरच असेल तर तुम्ही ती केली आहे हे तुम्ही विसरू शकत नाही. हेच कारण आहे की आपण कोणत्या सुपरक्लासचे `_beforeTokenTransfer` ओव्हरराइड करत आहोत हे नमूद करणे आवश्यक आहे.

```solidity
        super._beforeTokenTransfer(from, to, amount);
```

ही ओळ त्या कॉन्ट्रॅक्टच्या किंवा कॉन्ट्रॅक्ट्सच्या `_beforeTokenTransfer` फंक्शनला कॉल करते ज्यांच्याकडून आपण वारसा मिळवला आहे आणि ज्यांच्याकडे ते आहे. या प्रकरणात, ते फक्त `ERC20` आहे, `Ownable` कडे हा हूक नाही. जरी सध्या `ERC20._beforeTokenTransfer` काहीही करत नसले तरी, भविष्यात कार्यक्षमता जोडली गेल्यास आपण त्याला कॉल करतो (आणि नंतर आपण कॉन्ट्रॅक्ट पुन्हा प्रस्थापित करण्याचे ठरवतो, कारण प्रस्थापनेनंतर कॉन्ट्रॅक्ट्स बदलत नाहीत).

### आवश्यकतांचे कोडिंग करणे {#coding-the-requirements}

आम्हाला फंक्शनमध्ये या आवश्यकता जोडायच्या आहेत:

- `to` पत्ता `address(this)` च्या समान असू शकत नाही, जो स्वतः ERC-20 कॉन्ट्रॅक्टचा पत्ता आहे.
- `to` पत्ता रिकामा असू शकत नाही, तो यापैकी एक असणे आवश्यक आहे:
  - बाह्य मालकीचे खाते (EOA). एखादा पत्ता EOA आहे की नाही हे आपण थेट तपासू शकत नाही, परंतु आपण पत्त्याची ETH शिल्लक तपासू शकतो. EOA मध्ये जवळजवळ नेहमीच शिल्लक असते, जरी ते यापुढे वापरले जात नसले तरीही - त्यांना शेवटच्या Wei पर्यंत साफ करणे कठीण आहे.
  - एक स्मार्ट कॉन्ट्रॅक्ट. एखादा पत्ता स्मार्ट कॉन्ट्रॅक्ट आहे की नाही हे तपासणे थोडे कठीण आहे. बाह्य कोडची लांबी तपासणारा एक ऑपकोड आहे, ज्याला [`EXTCODESIZE`](https://www.evm.codes/#3b) म्हणतात, परंतु तो थेट Solidity मध्ये उपलब्ध नाही. त्यासाठी आपल्याला [Yul](https://docs.soliditylang.org/en/v0.8.15/yul.html) वापरावे लागेल, जे EVM असेंब्ली आहे. आपण Solidity मधून इतर मूल्ये वापरू शकतो ([`<address>.code` आणि `<address>.codehash`](https://docs.soliditylang.org/en/v0.8.15/units-and-global-variables.html#members-of-address-types)), परंतु त्यासाठी जास्त खर्च येतो.

चला नवीन कोड ओळीनुसार पाहूया:

```solidity
        require(to != address(this), "Can't send tokens to the contract address");
```

ही पहिली आवश्यकता आहे, `to` आणि `this(address)` समान नाहीत हे तपासा.

```solidity
        bool isToContract;
        assembly {
           isToContract := gt(extcodesize(to), 0)
        }
```

अशा प्रकारे आपण एखादा पत्ता कॉन्ट्रॅक्ट आहे की नाही हे तपासतो. आपण Yul कडून थेट आउटपुट प्राप्त करू शकत नाही, म्हणून त्याऐवजी आपण निकाल ठेवण्यासाठी एक व्हेरिएबल परिभाषित करतो (या प्रकरणात `isToContract`). Yul ज्या प्रकारे कार्य करते ते म्हणजे प्रत्येक ऑपकोड एक फंक्शन मानले जाते. म्हणून प्रथम आपण कॉन्ट्रॅक्टचा आकार मिळवण्यासाठी [`EXTCODESIZE`](https://www.evm.codes/#3b) ला कॉल करतो आणि नंतर ते शून्य नाही हे तपासण्यासाठी [`GT`](https://www.evm.codes/#11) वापरतो (आपण अनसाईन्ड इंटिजर्स हाताळत आहोत, त्यामुळे अर्थातच ते नकारात्मक असू शकत नाही). त्यानंतर आपण निकाल `isToContract` मध्ये लिहितो.

```solidity
        require(to.balance != 0 || isToContract, "Can't send tokens to an empty address");
```

आणि शेवटी, आपल्याकडे रिकाम्या पत्त्यांसाठी प्रत्यक्ष तपासणी आहे.

## प्रशासकीय प्रवेश {#admin-access}

कधीकधी चुका पूर्ववत करू शकणारा प्रशासक असणे उपयुक्त ठरते. गैरवापराची शक्यता कमी करण्यासाठी, हा प्रशासक [मल्टीसिग](https://blog.logrocket.com/security-choices-multi-signature-wallets/) असू शकतो जेणेकरून एका कृतीवर अनेक लोकांना सहमत व्हावे लागेल. या लेखात आपल्याकडे दोन प्रशासकीय वैशिष्ट्ये असतील:

1. खाती गोठवणे (Freezing) आणि पूर्ववत करणे (unfreezing). हे उपयुक्त ठरू शकते, उदाहरणार्थ, जेव्हा एखाद्या खात्याशी तडजोड (compromised) झाली असेल.
2. मालमत्ता स्वच्छता (Asset cleanup).

   कधीकधी फसवणूक करणारे कायदेशीरपणा मिळवण्यासाठी खऱ्या टोकनच्या कॉन्ट्रॅक्टवर फसव्या टोकन्स पाठवतात. उदाहरणार्थ, [येथे पहा](https://optimism.blockscout.com/token/0x2348B1a1228DDCd2dB668c3d30207c3E1852fBbe?tab=holders). कायदेशीर ERC-20 कॉन्ट्रॅक्ट [0x4200....0042](https://optimism.blockscout.com/token/0x4200000000000000000000000000000000000042) आहे. जो घोटाळा तसे असल्याचे भासवतो तो [0x234....bbe](https://optimism.blockscout.com/token/0x2348B1a1228DDCd2dB668c3d30207c3E1852fBbe) आहे.

   असेही होऊ शकते की लोक चुकून आपल्या कॉन्ट्रॅक्टवर कायदेशीर ERC-20 टोकन पाठवतात, जे त्यांना बाहेर काढण्याचा मार्ग हवा असण्याचे आणखी एक कारण आहे.

प्रशासकीय प्रवेश सक्षम करण्यासाठी ओपनझेपलिन दोन यंत्रणा प्रदान करते:

- [`Ownable`](https://docs.openzeppelin.com/contracts/5.x/access-control#ownership-and-ownable) कॉन्ट्रॅक्ट्सचा एकच मालक असतो. ज्या फंक्शन्समध्ये `onlyOwner` [मॉडिफायर](https://www.tutorialspoint.com/solidity/solidity_function_modifiers.htm) असतो त्यांना फक्त तोच मालक कॉल करू शकतो. मालक मालकी दुसऱ्या कोणाकडे हस्तांतरित करू शकतात किंवा ती पूर्णपणे सोडून देऊ शकतात. इतर सर्व खात्यांचे अधिकार सामान्यतः समान असतात.
- [`AccessControl`](https://docs.openzeppelin.com/contracts/5.x/access-control#role-based-access-control) कॉन्ट्रॅक्ट्समध्ये [भूमिका आधारित प्रवेश नियंत्रण (role based access control - RBAC)](https://en.wikipedia.org/wiki/Role-based_access_control) असते.

सोपेपणासाठी, या लेखात आपण `Ownable` वापरतो.

### कॉन्ट्रॅक्ट्स गोठवणे आणि पूर्ववत करणे (thawing) {#freezing-and-thawing-contracts}

कॉन्ट्रॅक्ट्स गोठवण्यासाठी आणि पूर्ववत करण्यासाठी अनेक बदलांची आवश्यकता असते:

- कोणते पत्ते गोठवले आहेत याचा मागोवा ठेवण्यासाठी पत्त्यांपासून [बुलियन्सपर्यंत](https://en.wikipedia.org/wiki/Boolean_data_type) एक [मॅपिंग](https://www.tutorialspoint.com/solidity/solidity_mappings.htm). सर्व मूल्ये सुरुवातीला शून्य असतात, ज्याचा बुलियन मूल्यांसाठी अर्थ 'खोटे' (false) असा होतो. आपल्याला हेच हवे आहे कारण डीफॉल्टनुसार खाती गोठवलेली नसतात.

  ```solidity
      mapping(address => bool) public frozenAccounts;
  ```

- जेव्हा एखादे खाते गोठवले जाते किंवा पूर्ववत केले जाते तेव्हा स्वारस्य असलेल्या कोणालाही माहिती देण्यासाठी [घटना](https://www.tutorialspoint.com/solidity/solidity_events.htm). तांत्रिकदृष्ट्या या कृतींसाठी घटना आवश्यक नाहीत, परंतु साखळीबाह्य (offchain) कोडला या घटना ऐकण्यास आणि काय घडत आहे हे जाणून घेण्यास मदत होते. जेव्हा दुसऱ्या कोणासाठी तरी संबंधित असू शकेल असे काहीतरी घडते तेव्हा स्मार्ट कॉन्ट्रॅक्टने त्यांना उत्सर्जित (emit) करणे हे चांगले शिष्टाचार मानले जाते.

  घटना अनुक्रमित (indexed) केल्या आहेत जेणेकरून खाते किती वेळा गोठवले गेले किंवा पूर्ववत केले गेले हे शोधणे शक्य होईल.

  ```solidity
    // जेव्हा खाती गोठवली जातात किंवा पूर्ववत केली जातात
    event AccountFrozen(address indexed _addr);
    event AccountThawed(address indexed _addr);
  ```

- खाती गोठवण्यासाठी आणि पूर्ववत करण्यासाठी फंक्शन्स. ही दोन फंक्शन्स जवळजवळ सारखीच आहेत, त्यामुळे आपण फक्त फ्रीझ फंक्शन पाहू.

  ```solidity
      function freezeAccount(address addr)
        public
        onlyOwner
  ```

  [`public`](https://www.tutorialspoint.com/solidity/solidity_contracts.htm) चिन्हांकित केलेली फंक्शन्स इतर स्मार्ट कॉन्ट्रॅक्ट्समधून किंवा थेट व्यवहाराद्वारे कॉल केली जाऊ शकतात.

  ```solidity
    {
        require(!frozenAccounts[addr], "Account already frozen");
        frozenAccounts[addr] = true;
        emit AccountFrozen(addr);
    }  // freezeAccount
  ```

  जर खाते आधीच गोठवलेले असेल, तर पूर्ववत करा. अन्यथा, ते गोठवा आणि एक घटना `emit` करा.

- गोठवलेल्या खात्यातून पैसे हलवण्यापासून रोखण्यासाठी `_beforeTokenTransfer` बदला. लक्षात घ्या की गोठवलेल्या खात्यात अद्याप पैसे हस्तांतरित केले जाऊ शकतात.

  ```solidity
       require(!frozenAccounts[from], "The account is frozen");
  ```

### मालमत्ता स्वच्छता {#asset-cleanup}

या कॉन्ट्रॅक्टद्वारे धारण केलेले ERC-20 टोकन सोडण्यासाठी आपल्याला ते ज्या टोकन कॉन्ट्रॅक्टचे आहेत त्यावरील फंक्शनला कॉल करणे आवश्यक आहे, एकतर [`transfer`](https://eips.ethereum.org/EIPS/eip-20#transfer) किंवा [`approve`](https://eips.ethereum.org/EIPS/eip-20#approve). या प्रकरणात भत्त्यांवर (allowances) गॅस वाया घालवण्यात काही अर्थ नाही, आपण थेट हस्तांतरण करू शकतो.

```solidity
    function cleanupERC20(
        address erc20,
        address dest
    )
        public
        onlyOwner
    {
        IERC20 token = IERC20(erc20);
```

जेव्हा आपल्याला पत्ता प्राप्त होतो तेव्हा कॉन्ट्रॅक्टसाठी ऑब्जेक्ट तयार करण्याचा हा सिंटॅक्स आहे. आपण हे करू शकतो कारण आपल्याकडे सोर्स कोडचा भाग म्हणून ERC20 टोकन्सची व्याख्या आहे (ओळ 4 पहा), आणि त्या फाईलमध्ये [IERC20 ची व्याख्या](https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC20/IERC20.sol) समाविष्ट आहे, जो ओपनझेपलिन ERC-20 कॉन्ट्रॅक्टसाठी इंटरफेस आहे.

```solidity
        uint balance = token.balanceOf(address(this));
        token.transfer(dest, balance);
    }
```

हे एक स्वच्छता (cleanup) फंक्शन आहे, त्यामुळे बहुधा आपल्याला कोणतेही टोकन सोडायचे नाहीत. वापरकर्त्याकडून मॅन्युअली शिल्लक मिळवण्याऐवजी, आपण ही प्रक्रिया स्वयंचलित करू शकतो.

## निष्कर्ष {#conclusion}

हा एक परिपूर्ण उपाय नाही - "वापरकर्त्याने चूक केली" या समस्येवर कोणताही परिपूर्ण उपाय नाही. तथापि, या प्रकारच्या तपासण्या वापरल्याने किमान काही चुका टाळता येऊ शकतात. खाती गोठवण्याची क्षमता, जरी धोकादायक असली तरी, हॅकरला चोरीला गेलेला निधी नाकारून काही हॅक्सचे नुकसान मर्यादित करण्यासाठी वापरली जाऊ शकते.

[माझ्या अधिक कामासाठी येथे पहा](https://cryptodocguy.pro/).