স্মার্ট কন্ট্রাক্ট টেস্ট করতে কীভাবে Echidna ব্যবহার করবেন

ইনস্টলেশন

Echidna ডকার (docker) এর মাধ্যমে বা প্রি-কম্পাইল করা বাইনারি ব্যবহার করে ইনস্টল করা যেতে পারে।

ডকারের মাধ্যমে Echidna

docker pull trailofbits/eth-security-toolbox
docker run -it -v "$PWD":/home/training trailofbits/eth-security-toolbox

শেষ কমান্ডটি eth-security-toolbox-কে এমন একটি ডকারে রান করে যার আপনার বর্তমান ডিরেক্টরিতে অ্যাক্সেস রয়েছে। আপনি আপনার হোস্ট থেকে ফাইলগুলো পরিবর্তন করতে পারেন এবং ডকার থেকে ফাইলগুলোর ওপর টুলগুলো রান করতে পারেন।

ডকারের ভেতরে রান করুন:

solc-select 0.5.11
cd /home/training

বাইনারি

https://github.com/crytic/echidna/releases/tag/v1.4.0.0 (opens in a new tab)

প্রপার্টি-ভিত্তিক ফাজিং (fuzzing) পরিচিতি

Echidna হলো একটি প্রপার্টি-ভিত্তিক ফাজার, যা আমরা আমাদের আগের ব্লগপোস্টগুলোতে বর্ণনা করেছি (1 (opens in a new tab), 2 (opens in a new tab), 3 (opens in a new tab))।

ফাজিং

ফাজিং (opens in a new tab) হলো নিরাপত্তা কমিউনিটিতে একটি সুপরিচিত কৌশল। প্রোগ্রামে বাগ (bug) খুঁজে বের করার জন্য কমবেশি র‍্যান্ডম ইনপুট তৈরি করা এর কাজ। প্রথাগত সফটওয়্যারের জন্য ফাজারগুলো (যেমন AFL (opens in a new tab) বা LibFuzzer (opens in a new tab)) বাগ খুঁজে বের করার কার্যকর টুল হিসেবে পরিচিত।

সম্পূর্ণ র‍্যান্ডম ইনপুট তৈরির বাইরেও, ভালো ইনপুট তৈরি করার জন্য অনেক কৌশল এবং পদ্ধতি রয়েছে, যার মধ্যে অন্তর্ভুক্ত:

• প্রতিটি এক্সিকিউশন থেকে ফিডব্যাক নেওয়া এবং এটি ব্যবহার করে জেনারেশন গাইড করা। উদাহরণস্বরূপ, যদি একটি নতুন তৈরি করা ইনপুট নতুন কোনো পাথ (path) আবিষ্কার করতে সাহায্য করে, তবে এর কাছাকাছি নতুন ইনপুট তৈরি করা যৌক্তিক হতে পারে।
• কাঠামোগত সীমাবদ্ধতা মেনে ইনপুট তৈরি করা। উদাহরণস্বরূপ, যদি আপনার ইনপুটে চেকসাম (checksum) সহ একটি হেডার থাকে, তবে ফাজারকে চেকসাম যাচাই করার মতো ইনপুট তৈরি করতে দেওয়া যৌক্তিক হবে।
• নতুন ইনপুট তৈরি করতে পরিচিত ইনপুট ব্যবহার করা: যদি আপনার কাছে বৈধ ইনপুটের একটি বড় ডেটাসেট থাকে, তবে আপনার ফাজার শূন্য থেকে শুরু করার পরিবর্তে সেগুলো থেকে নতুন ইনপুট তৈরি করতে পারে। এগুলোকে সাধারণত সীড (seeds) বলা হয়।

প্রপার্টি-ভিত্তিক ফাজিং

Echidna ফাজারের একটি নির্দিষ্ট পরিবারের অন্তর্গত: প্রপার্টি-ভিত্তিক ফাজিং যা QuickCheck (opens in a new tab) দ্বারা ব্যাপকভাবে অনুপ্রাণিত। ক্লাসিক ফাজারের বিপরীতে যা ক্র্যাশ খুঁজে বের করার চেষ্টা করে, Echidna ব্যবহারকারী-নির্ধারিত ইনভ্যারিয়েন্টগুলো (invariants) ভাঙার চেষ্টা করবে।

স্মার্ট কন্ট্রাক্ট-এ, ইনভ্যারিয়েন্টগুলো হলো Solidity ফাংশন, যা কন্ট্রাক্ট পৌঁছাতে পারে এমন যেকোনো ভুল বা অবৈধ স্টেট (state) উপস্থাপন করতে পারে, যার মধ্যে রয়েছে:

• ভুল অ্যাক্সেস কন্ট্রোল: আক্রমণকারী কন্ট্রাক্টের মালিক হয়ে গেছে।
• ভুল স্টেট মেশিন: কন্ট্রাক্ট পজ (pause) থাকা অবস্থায় টোকেন ট্রান্সফার করা যেতে পারে।
• ভুল পাটিগণিত: ব্যবহারকারী তার ব্যালেন্স আন্ডারফ্লো (underflow) করতে পারে এবং আনলিমিটেড ফ্রি টোকেন পেতে পারে।

Echidna দিয়ে একটি প্রপার্টি টেস্ট করা

আমরা দেখব কীভাবে Echidna দিয়ে একটি স্মার্ট কন্ট্রাক্ট টেস্ট করতে হয়। লক্ষ্য হলো নিচের স্মার্ট কন্ট্রাক্টটি token.sol (opens in a new tab):

1contract Token{
2  mapping(address => uint) public balances;
3  function airdrop() public{
4      balances[msg.sender] = 1000;
5  }
6  function consume() public{
7      require(balances[msg.sender]>0);
8      balances[msg.sender] -= 1;
9  }
10  function backdoor() public{
11      balances[msg.sender] += 1;
12  }
13}
সব দেখান
কপি করুন

আমরা ধরে নেব যে এই টোকেনের নিচের প্রপার্টিগুলো থাকতে হবে:

• যেকোনো ব্যক্তির কাছে সর্বোচ্চ 1000 টোকেন থাকতে পারে
• টোকেনটি ট্রান্সফার করা যাবে না (এটি কোনো ERC-20 টোকেন নয়)

একটি প্রপার্টি লেখা

Echidna প্রপার্টিগুলো হলো Solidity ফাংশন। একটি প্রপার্টিতে অবশ্যই:

• কোনো আর্গুমেন্ট থাকা যাবে না
• সফল হলে true রিটার্ন করতে হবে
• এর নাম echidna দিয়ে শুরু হতে হবে

Echidna যা করবে:

• প্রপার্টি টেস্ট করার জন্য স্বয়ংক্রিয়ভাবে আরবিট্রারি লেনদেন তৈরি করবে।
• কোনো লেনদেন যদি প্রপার্টিকে false রিটার্ন করায় বা এরর (error) থ্রো করে, তবে তা রিপোর্ট করবে।
• প্রপার্টি কল করার সময় সাইড-ইফেক্ট বাতিল করবে (অর্থাৎ, যদি প্রপার্টি কোনো স্টেট ভেরিয়েবল পরিবর্তন করে, তবে টেস্টের পরে তা বাতিল করা হয়)

নিচের প্রপার্টিটি চেক করে যে কলারের কাছে 1000-এর বেশি টোকেন নেই:

1function echidna_balance_under_1000() public view returns(bool){
2      return balances[msg.sender] <= 1000;
3}
কপি করুন

আপনার কন্ট্রাক্টকে প্রপার্টিগুলো থেকে আলাদা করতে ইনহেরিটেন্স (inheritance) ব্যবহার করুন:

1contract TestToken is Token{
2      function echidna_balance_under_1000() public view returns(bool){
3            return balances[msg.sender] <= 1000;
4      }
5  }
কপি করুন

token.sol (opens in a new tab) প্রপার্টিটি ইমপ্লিমেন্ট করে এবং টোকেন থেকে ইনহেরিট করে।

একটি কন্ট্রাক্ট ইনিশিয়েট করা

Echidna-এর জন্য আর্গুমেন্ট ছাড়া একটি কনস্ট্রাক্টর প্রয়োজন। যদি আপনার কন্ট্রাক্টে নির্দিষ্ট কোনো ইনিশিয়ালাইজেশনের প্রয়োজন হয়, তবে আপনাকে তা কনস্ট্রাক্টরে করতে হবে।

Echidna-তে কিছু নির্দিষ্ট এডড্রেস রয়েছে:

• 0x00a329c0648769A73afAc7F9381E08FB43dBEA72 যা কনস্ট্রাক্টরকে কল করে।
• 0x10000, 0x20000, এবং 0x00a329C0648769a73afAC7F9381e08fb43DBEA70 যা র‍্যান্ডমভাবে অন্যান্য ফাংশনগুলোকে কল করে।

আমাদের বর্তমান উদাহরণে কোনো নির্দিষ্ট ইনিশিয়ালাইজেশনের প্রয়োজন নেই, যার ফলে আমাদের কনস্ট্রাক্টরটি ফাঁকা।

Echidna রান করা

Echidna চালু করা হয় এভাবে:

echidna-test contract.sol

যদি contract.sol-এ একাধিক কন্ট্রাক্ট থাকে, তবে আপনি টার্গেট নির্দিষ্ট করতে পারেন:

echidna-test contract.sol --contract MyContract

সারসংক্ষেপ: একটি প্রপার্টি টেস্ট করা

নিচে আমাদের উদাহরণে echidna রান করার সারসংক্ষেপ দেওয়া হলো:

1contract TestToken is Token{
2    constructor() public {}
3        function echidna_balance_under_1000() public view returns(bool){
4          return balances[msg.sender] <= 1000;
5        }
6  }
কপি করুন

echidna-test testtoken.sol --contract TestToken
...
echidna_balance_under_1000: failed!💥
  Call sequence, shrinking (1205/5000):
    airdrop()
    backdoor()
...
সব দেখান

Echidna দেখতে পেয়েছে যে backdoor কল করা হলে প্রপার্টিটি লঙ্ঘিত হয়।

ফাজিং ক্যাম্পেইনের সময় কল করার জন্য ফাংশন ফিল্টার করা

আমরা দেখব কীভাবে ফাজ (fuzz) করার জন্য ফাংশনগুলো ফিল্টার করতে হয়। লক্ষ্য হলো নিচের স্মার্ট কন্ট্রাক্টটি:

1contract C {
2  bool state1 = false;
3  bool state2 = false;
4  bool state3 = false;
5  bool state4 = false;
6
7  function f(uint x) public {
8    require(x == 12);
9    state1 = true;
10  }
11
12  function g(uint x) public {
13    require(state1);
14    require(x == 8);
15    state2 = true;
16  }
17
18  function h(uint x) public {
19    require(state2);
20    require(x == 42);
21    state3 = true;
22  }
23
24 function i() public {
25    require(state3);
26    state4 = true;
27  }
28
29  function reset1() public {
30    state1 = false;
31    state2 = false;
32    state3 = false;
33    return;
34  }
35
36  function reset2() public {
37    state1 = false;
38    state2 = false;
39    state3 = false;
40    return;
41  }
42
43  function echidna_state4() public returns (bool) {
44    return (!state4);
45  }
46}
সব দেখান
কপি করুন

এই ছোট উদাহরণটি Echidna-কে একটি স্টেট ভেরিয়েবল পরিবর্তন করার জন্য লেনদেনের একটি নির্দিষ্ট সিকোয়েন্স খুঁজে বের করতে বাধ্য করে। এটি একটি ফাজারের জন্য কঠিন (এর জন্য Manticore (opens in a new tab)-এর মতো একটি সিম্বলিক এক্সিকিউশন টুল ব্যবহার করার পরামর্শ দেওয়া হয়)। এটি যাচাই করার জন্য আমরা Echidna রান করতে পারি:

echidna-test multi.sol
...
echidna_state4: passed! 🎉
Seed: -3684648582249875403

ফাংশন ফিল্টার করা

এই কন্ট্রাক্টটি টেস্ট করার জন্য সঠিক সিকোয়েন্স খুঁজে পেতে Echidna-র সমস্যা হয় কারণ দুটি রিসেট ফাংশন (reset1 এবং reset2) সমস্ত স্টেট ভেরিয়েবলকে false-এ সেট করে দেবে। যাইহোক, আমরা রিসেট ফাংশনটিকে ব্ল্যাকলিস্ট করতে বা শুধুমাত্র f, g, h এবং i ফাংশনগুলোকে হোয়াইটলিস্ট করতে একটি বিশেষ Echidna ফিচার ব্যবহার করতে পারি।

ফাংশন ব্ল্যাকলিস্ট করতে, আমরা এই কনফিগারেশন ফাইলটি ব্যবহার করতে পারি:

1filterBlacklist: true
2filterFunctions: ["reset1", "reset2"]

ফাংশন ফিল্টার করার আরেকটি পদ্ধতি হলো হোয়াইটলিস্ট করা ফাংশনগুলোর তালিকা করা। এটি করার জন্য, আমরা এই কনফিগারেশন ফাইলটি ব্যবহার করতে পারি:

1filterBlacklist: false
2filterFunctions: ["f", "g", "h", "i"]

• filterBlacklist ডিফল্টভাবে true থাকে।
• ফিল্টারিং শুধুমাত্র নাম দিয়ে করা হবে (প্যারামিটার ছাড়া)। যদি আপনার f() এবং f(uint256) থাকে, তবে "f" ফিল্টারটি উভয় ফাংশনের সাথেই মিলবে।

Echidna রান করা

একটি কনফিগারেশন ফাইল blacklist.yaml দিয়ে Echidna রান করতে:

echidna-test multi.sol --config blacklist.yaml
...
echidna_state4: failed!💥
  Call sequence:
    f(12)
    g(8)
    h(42)
    i()

Echidna প্রায় সাথে সাথেই প্রপার্টিটিকে ভুল প্রমাণ করার জন্য লেনদেনের সিকোয়েন্স খুঁজে পাবে।

সারসংক্ষেপ: ফাংশন ফিল্টার করা

Echidna ফাজিং ক্যাম্পেইনের সময় কল করার জন্য ফাংশনগুলোকে ব্ল্যাকলিস্ট বা হোয়াইটলিস্ট করতে পারে, যা ব্যবহার করে:

1filterBlacklist: true
2filterFunctions: ["f1", "f2", "f3"]

echidna-test contract.sol --config config.yaml
...

Echidna filterBlacklist বুলিয়ানের মানের ওপর ভিত্তি করে f1, f2 এবং f3 ব্ল্যাকলিস্ট করে অথবা শুধুমাত্র এগুলোকে কল করে একটি ফাজিং ক্যাম্পেইন শুরু করে।

Echidna দিয়ে Solidity-এর assert কীভাবে টেস্ট করবেন

এই সংক্ষিপ্ত টিউটোরিয়ালে, আমরা দেখাব কীভাবে কন্ট্রাক্টে অ্যাসারশন (assertion) চেকিং টেস্ট করতে Echidna ব্যবহার করতে হয়। ধরুন আমাদের কাছে এরকম একটি কন্ট্রাক্ট আছে:

1contract Incrementor {
2  uint private counter = 2**200;
3
4  function inc(uint val) public returns (uint){
5    uint tmp = counter;
6    counter += val;
7    // tmp <= counter
8    return (counter - tmp);
9  }
10}
সব দেখান
কপি করুন

একটি অ্যাসারশন লেখা

আমরা নিশ্চিত করতে চাই যে এর পার্থক্য রিটার্ন করার পরে tmp যেন counter-এর চেয়ে কম বা সমান হয়। আমরা একটি Echidna প্রপার্টি লিখতে পারতাম, কিন্তু আমাদের tmp মানটি কোথাও স্টোর করতে হবে। এর পরিবর্তে, আমরা এরকম একটি অ্যাসারশন ব্যবহার করতে পারি:

1contract Incrementor {
2  uint private counter = 2**200;
3
4  function inc(uint val) public returns (uint){
5    uint tmp = counter;
6    counter += val;
7    assert (tmp <= counter);
8    return (counter - tmp);
9  }
10}
সব দেখান
কপি করুন

Echidna রান করা

অ্যাসারশন ফেইলিওর টেস্টিং চালু করতে, একটি Echidna কনফিগারেশন ফাইল (opens in a new tab) config.yaml তৈরি করুন:

1checkAsserts: true

যখন আমরা Echidna-তে এই কন্ট্রাক্টটি রান করি, তখন আমরা প্রত্যাশিত ফলাফল পাই:

echidna-test assert.sol --config config.yaml
Analyzing contract: assert.sol:Incrementor
assertion in inc: failed!💥
  Call sequence, shrinking (2596/5000):
    inc(21711016731996786641919559689128982722488122124807605757398297001483711807488)
    inc(7237005577332262213973186563042994240829374041602535252466099000494570602496)
    inc(86844066927987146567678238756515930889952488499230423029593188005934847229952)
Seed: 1806480648350826486
সব দেখান

যেমনটি আপনি দেখতে পাচ্ছেন, Echidna inc ফাংশনে কিছু অ্যাসারশন ফেইলিওর রিপোর্ট করে। প্রতি ফাংশনে একাধিক অ্যাসারশন যোগ করা সম্ভব, তবে কোন অ্যাসারশনটি ব্যর্থ হয়েছে তা Echidna বলতে পারে না।

কখন এবং কীভাবে অ্যাসারশন ব্যবহার করবেন

অ্যাসারশনগুলো এক্সপ্লিসিট প্রপার্টির বিকল্প হিসেবে ব্যবহার করা যেতে পারে, বিশেষ করে যদি চেক করার শর্তগুলো সরাসরি কোনো অপারেশন f-এর সঠিক ব্যবহারের সাথে সম্পর্কিত হয়। কিছু কোডের পরে অ্যাসারশন যোগ করলে তা নিশ্চিত করবে যে এটি এক্সিকিউট হওয়ার পরপরই চেক করা হবে:

1function f(..) public {
2    // কিছু জটিল কোড
3    ...
4    assert (condition);
5    ...
6}
7
কপি করুন

বিপরীতভাবে, একটি এক্সপ্লিসিট echidna প্রপার্টি ব্যবহার করলে তা র‍্যান্ডমভাবে লেনদেন এক্সিকিউট করবে এবং এটি ঠিক কখন চেক করা হবে তা নিশ্চিত করার কোনো সহজ উপায় নেই। তবে এই ওয়ার্কঅ্যারাউন্ডটি করা এখনও সম্ভব:

1function echidna_assert_after_f() public returns (bool) {
2    f(..);
3    return(condition);
4}
কপি করুন

যাইহোক, কিছু সমস্যা রয়েছে:

• যদি f-কে internal বা external হিসেবে ডিক্লেয়ার করা হয় তবে এটি ব্যর্থ হয়।
• f কল করার জন্য কোন আর্গুমেন্টগুলো ব্যবহার করা উচিত তা অস্পষ্ট।
• যদি f রিভার্ট (revert) করে, তবে প্রপার্টিটি ব্যর্থ হবে।

সাধারণভাবে, আমরা অ্যাসারশন কীভাবে ব্যবহার করতে হয় সে সম্পর্কে জন রেগেহরের সুপারিশ (opens in a new tab) অনুসরণ করার পরামর্শ দিই:

• অ্যাসারশন চেকিংয়ের সময় কোনো সাইড ইফেক্ট জোর করে প্রয়োগ করবেন না। উদাহরণস্বরূপ: assert(ChangeStateAndReturn() == 1)
• সুস্পষ্ট স্টেটমেন্ট অ্যাসার্ট করবেন না। উদাহরণস্বরূপ assert(var >= 0) যেখানে var-কে uint হিসেবে ডিক্লেয়ার করা হয়েছে।

পরিশেষে, অনুগ্রহ করে assert-এর পরিবর্তে require ব্যবহার করবেন না, কারণ Echidna এটি শনাক্ত করতে পারবে না (তবে কন্ট্রাক্টটি যেভাবেই হোক রিভার্ট করবে)।

সারসংক্ষেপ: অ্যাসারশন চেকিং

নিচে আমাদের উদাহরণে echidna রান করার সারসংক্ষেপ দেওয়া হলো:

1contract Incrementor {
2  uint private counter = 2**200;
3
4  function inc(uint val) public returns (uint){
5    uint tmp = counter;
6    counter += val;
7    assert (tmp <= counter);
8    return (counter - tmp);
9  }
10}
সব দেখান
কপি করুন

echidna-test assert.sol --config config.yaml
Analyzing contract: assert.sol:Incrementor
assertion in inc: failed!💥
  Call sequence, shrinking (2596/5000):
    inc(21711016731996786641919559689128982722488122124807605757398297001483711807488)
    inc(7237005577332262213973186563042994240829374041602535252466099000494570602496)
    inc(86844066927987146567678238756515930889952488499230423029593188005934847229952)
Seed: 1806480648350826486
সব দেখান

Echidna দেখতে পেয়েছে যে inc-এর অ্যাসারশনটি ব্যর্থ হতে পারে যদি এই ফাংশনটি বড় আর্গুমেন্ট দিয়ে একাধিকবার কল করা হয়।

একটি Echidna কর্পাস (corpus) সংগ্রহ এবং পরিবর্তন করা

আমরা দেখব কীভাবে Echidna দিয়ে লেনদেনের একটি কর্পাস সংগ্রহ এবং ব্যবহার করতে হয়। লক্ষ্য হলো নিচের স্মার্ট কন্ট্রাক্টটি magic.sol (opens in a new tab):

1contract C {
2  bool value_found = false;
3  function magic(uint magic_1, uint magic_2, uint magic_3, uint magic_4) public {
4    require(magic_1 == 42);
5    require(magic_2 == 129);
6    require(magic_3 == magic_4+333);
7    value_found = true;
8    return;
9  }
10
11  function echidna_magic_values() public returns (bool) {
12    return !value_found;
13  }
14
15}
সব দেখান
কপি করুন

এই ছোট উদাহরণটি Echidna-কে একটি স্টেট ভেরিয়েবল পরিবর্তন করার জন্য নির্দিষ্ট মান খুঁজে বের করতে বাধ্য করে। এটি একটি ফাজারের জন্য কঠিন (এর জন্য Manticore (opens in a new tab)-এর মতো একটি সিম্বলিক এক্সিকিউশন টুল ব্যবহার করার পরামর্শ দেওয়া হয়)। এটি যাচাই করার জন্য আমরা Echidna রান করতে পারি:

echidna-test magic.sol
...
echidna_magic_values: passed! 🎉
Seed: 2221503356319272685

যাইহোক, এই ফাজিং ক্যাম্পেইন রান করার সময় আমরা এখনও কর্পাস সংগ্রহ করতে Echidna ব্যবহার করতে পারি।

একটি কর্পাস সংগ্রহ করা

কর্পাস সংগ্রহ চালু করতে, একটি কর্পাস ডিরেক্টরি তৈরি করুন:

mkdir corpus-magic

এবং একটি Echidna কনফিগারেশন ফাইল (opens in a new tab) config.yaml:

1coverage: true
2corpusDir: "corpus-magic"

এখন আমরা আমাদের টুলটি রান করতে পারি এবং সংগৃহীত কর্পাস চেক করতে পারি:

echidna-test magic.sol --config config.yaml

Echidna এখনও সঠিক ম্যাজিক মানগুলো খুঁজে পাচ্ছে না, তবে আমরা এর সংগৃহীত কর্পাসটি দেখতে পারি। উদাহরণস্বরূপ, এই ফাইলগুলোর মধ্যে একটি ছিল:

1[
2  {
3    "_gas'": "0xffffffff",
4    "_delay": ["0x13647", "0xccf6"],
5    "_src": "00a329c0648769a73afac7f9381e08fb43dbea70",
6    "_dst": "00a329c0648769a73afac7f9381e08fb43dbea72",
7    "_value": "0x0",
8    "_call": {
9      "tag": "SolCall",
10      "contents": [
11        "magic",
12        [
13          {
14            "contents": [
15              256,
16              "93723985220345906694500679277863898678726808528711107336895287282192244575836"
17            ],
18            "tag": "AbiUInt"
19          },
20          {
21            "contents": [256, "334"],
22            "tag": "AbiUInt"
23          },
24          {
25            "contents": [
26              256,
27              "68093943901352437066264791224433559271778087297543421781073458233697135179558"
28            ],
29            "tag": "AbiUInt"
30          },
31          {
32            "tag": "AbiUInt",
33            "contents": [256, "332"]
34          }
35        ]
36      ]
37    },
38    "_gasprice'": "0xa904461f1"
39  }
40]
সব দেখান
কপি করুন

স্পষ্টতই, এই ইনপুটটি আমাদের প্রপার্টিতে ফেইলিওর ট্রিগার করবে না। যাইহোক, পরবর্তী ধাপে, আমরা দেখব কীভাবে এর জন্য এটিকে পরিবর্তন করতে হয়।

একটি কর্পাস সীডিং (seeding) করা

magic ফাংশনটি নিয়ে কাজ করার জন্য Echidna-র কিছু সাহায্য প্রয়োজন। আমরা এর জন্য উপযুক্ত প্যারামিটার ব্যবহার করতে ইনপুটটি কপি এবং পরিবর্তন করতে যাচ্ছি:

cp corpus/2712688662897926208.txt corpus/new.txt

আমরা magic(42,129,333,0) কল করার জন্য new.txt পরিবর্তন করব। এখন, আমরা Echidna পুনরায় রান করতে পারি:

echidna-test magic.sol --config config.yaml
...
echidna_magic_values: failed!💥
  Call sequence:
    magic(42,129,333,0)
Unique instructions: 142
Unique codehashes: 1
Seed: -7293830866560616537
সব দেখান

এবার, এটি দেখতে পেয়েছে যে প্রপার্টিটি সাথে সাথেই লঙ্ঘিত হয়েছে।

উচ্চ গ্যাস (gas) খরচ সহ লেনদেন খুঁজে বের করা

আমরা দেখব কীভাবে Echidna দিয়ে উচ্চ গ্যাস খরচ সহ লেনদেন খুঁজে বের করতে হয়। লক্ষ্য হলো নিচের স্মার্ট কন্ট্রাক্টটি:

1contract C {
2  uint state;
3
4  function expensive(uint8 times) internal {
5    for(uint8 i=0; i < times; i++)
6      state = state + i;
7  }
8
9  function f(uint x, uint y, uint8 times) public {
10    if (x == 42 && y == 123)
11      expensive(times);
12    else
13      state = 0;
14  }
15
16  function echidna_test() public returns (bool) {
17    return true;
18  }
19
20}
সব দেখান
কপি করুন

এখানে expensive-এর একটি বড় গ্যাস খরচ থাকতে পারে।

বর্তমানে, Echidna-র টেস্ট করার জন্য সবসময় একটি প্রপার্টি প্রয়োজন হয়: এখানে echidna_test সবসময় true রিটার্ন করে। এটি যাচাই করার জন্য আমরা Echidna রান করতে পারি:

1echidna-test gas.sol
2...
3echidna_test: passed! 🎉
4
5Seed: 2320549945714142710

গ্যাস খরচ পরিমাপ করা

Echidna দিয়ে গ্যাস খরচ পরিমাপ চালু করতে, একটি কনফিগারেশন ফাইল config.yaml তৈরি করুন:

1estimateGas: true

এই উদাহরণে, ফলাফলগুলো সহজে বোঝার জন্য আমরা লেনদেনের সিকোয়েন্সের আকারও কমিয়ে দেব:

1seqLen: 2
2estimateGas: true

Echidna রান করা

একবার কনফিগারেশন ফাইল তৈরি হয়ে গেলে, আমরা এভাবে Echidna রান করতে পারি:

echidna-test gas.sol --config config.yaml
...
echidna_test: passed! 🎉
f used a maximum of 1333608 gas
  Call sequence:
    f(42,123,249) Gas price: 0x10d5733f0a Time delay: 0x495e5 Block delay: 0x88b2
Unique instructions: 157
Unique codehashes: 1
Seed: -325611019680165325
সব দেখান

• দেখানো গ্যাস হলো HEVM (opens in a new tab) দ্বারা প্রদত্ত একটি অনুমান।

গ্যাস-হ্রাসকারী কলগুলো ফিল্টার করা

ওপরের ফাজিং ক্যাম্পেইনের সময় কল করার জন্য ফাংশন ফিল্টার করা টিউটোরিয়ালটি দেখায় কীভাবে আপনার টেস্টিং থেকে কিছু ফাংশন সরিয়ে ফেলতে হয়।
একটি সঠিক গ্যাস অনুমান পাওয়ার জন্য এটি অত্যন্ত গুরুত্বপূর্ণ হতে পারে। নিচের উদাহরণটি বিবেচনা করুন:

1contract C {
2  address [] addrs;
3  function push(address a) public {
4    addrs.push(a);
5  }
6  function pop() public {
7    addrs.pop();
8  }
9  function clear() public{
10    addrs.length = 0;
11  }
12  function check() public{
13    for(uint256 i = 0; i < addrs.length; i++)
14      for(uint256 j = i+1; j < addrs.length; j++)
15        if (addrs[i] == addrs[j])
16          addrs[j] = address(0x0);
17  }
18  function echidna_test() public returns (bool) {
19      return true;
20  }
21}
সব দেখান
কপি করুন

যদি Echidna সমস্ত ফাংশন কল করতে পারে, তবে এটি সহজে উচ্চ গ্যাস খরচ সহ লেনদেন খুঁজে পাবে না:

1echidna-test pushpop.sol --config config.yaml
2...
3pop used a maximum of 10746 gas
4...
5check used a maximum of 23730 gas
6...
7clear used a maximum of 35916 gas
8...
9push used a maximum of 40839 gas
সব দেখান

এর কারণ হলো খরচটি addrs-এর আকারের ওপর নির্ভর করে এবং র‍্যান্ডম কলগুলো অ্যারেকে (array) প্রায় ফাঁকা রাখার প্রবণতা দেখায়। যাইহোক, pop এবং clear ব্ল্যাকলিস্ট করা আমাদের অনেক ভালো ফলাফল দেয়:

1filterBlacklist: true
2filterFunctions: ["pop", "clear"]

1echidna-test pushpop.sol --config config.yaml
2...
3push used a maximum of 40839 gas
4...
5check used a maximum of 1484472 gas

সারসংক্ষেপ: উচ্চ গ্যাস খরচ সহ লেনদেন খুঁজে বের করা

Echidna estimateGas কনফিগারেশন অপশন ব্যবহার করে উচ্চ গ্যাস খরচ সহ লেনদেন খুঁজে পেতে পারে:

1estimateGas: true

echidna-test contract.sol --config config.yaml
...

ফাজিং ক্যাম্পেইন শেষ হওয়ার পরে, Echidna প্রতিটি ফাংশনের জন্য সর্বোচ্চ গ্যাস খরচ সহ একটি সিকোয়েন্স রিপোর্ট করবে।

পেজ সর্বশেষ আপডেট: ২১ অক্টোবর, ২০২৫

p (opens in a new tab)

n (opens in a new tab)

M (opens in a new tab)

+9

অবদানকারীদের দেখুন