通过 Solidity 智能合约转移和批准 ERC-20 代币

智能合同

通证

Solidity

erc-20

中级

jdourlens

EthereumDev

2020年4月7日

9 分钟阅读

在之前的教程中，我们研究了以太坊区块链上用 Solidity 编写的 ERC-20 代币的结构。在本文中，我们将了解如何使用 Solidity 语言通过智能合约与代币进行交互。

对于此智能合约，我们将创建一个示例去中心化交易所，用户可以用以太币交易我们新部署的 ERC-20 代币。

在本教程中，我们将使用在上一篇教程中编写的代码作为基础。我们的 DEX 将在其构造函数中实例化一个合约实例，并执行以下操作：

将代币兑换成 ETH
将 ETH 兑换成代币

我们将通过添加简单的 ERC20 代码库来开启去中心化交易所代码：

1pragma solidity ^0.8.0;
2
3interface IERC20 {
4
5    function totalSupply() external view returns (uint256);
6    function balanceOf(address account) external view returns (uint256);
7    function allowance(address owner, address spender) external view returns (uint256);
8
9    function transfer(address recipient, uint256 amount) external returns (bool);
10    function approve(address spender, uint256 amount) external returns (bool);
11    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);
12
13
14    event Transfer(address indexed from, address indexed to, uint256 value);
15    event Approval(address indexed owner, address indexed spender, uint256 value);
16}
17
18
19contract ERC20Basic is IERC20 {
20
21    string public constant name = "ERC20Basic";
22    string public constant symbol = "ERC";
23    uint8 public constant decimals = 18;
24
25
26    mapping(address => uint256) balances;
27
28    mapping(address => mapping (address => uint256)) allowed;
29
30    uint256 totalSupply_ = 10 ether;
31
32
33   constructor() {
34	balances[msg.sender] = totalSupply_;
35    }
36
37    function totalSupply() public override view returns (uint256) {
38	return totalSupply_;
39    }
40
41    function balanceOf(address tokenOwner) public override view returns (uint256) {
42        return balances[tokenOwner];
43    }
44
45    function transfer(address receiver, uint256 numTokens) public override returns (bool) {
46        require(numTokens <= balances[msg.sender]);
47        balances[msg.sender] = balances[msg.sender]-numTokens;
48        balances[receiver] = balances[receiver]+numTokens;
49        emit Transfer(msg.sender, receiver, numTokens);
50        return true;
51    }
52
53    function approve(address delegate, uint256 numTokens) public override returns (bool) {
54        allowed[msg.sender][delegate] = numTokens;
55        emit Approval(msg.sender, delegate, numTokens);
56        return true;
57    }
58
59    function allowance(address owner, address delegate) public override view returns (uint) {
60        return allowed[owner][delegate];
61    }
62
63    function transferFrom(address owner, address buyer, uint256 numTokens) public override returns (bool) {
64        require(numTokens <= balances[owner]);
65        require(numTokens <= allowed[owner][msg.sender]);
66
67        balances[owner] = balances[owner]-numTokens;
68        allowed[owner][msg.sender] = allowed[owner][msg.sender]-numTokens;
69        balances[buyer] = balances[buyer]+numTokens;
70        emit Transfer(owner, buyer, numTokens);
71        return true;
72    }
73}
74
75
显示全部

我们新的 DEX 智能合约将部署 ERC-20 并获得全部代币供应：

1contract DEX {
2
3    IERC20 public token;
4
5    event Bought(uint256 amount);
6    event Sold(uint256 amount);
7
8    constructor() {
9        token = new ERC20Basic();
10    }
11
12    function buy() payable public {
13        // 待办
14    }
15
16    function sell(uint256 amount) public {
17        // 待办
18    }
19
20}
显示全部

所以我们现在有了我们的 DEX，它所有的代币储备都已准备好。合约有两个函数：

buy：用户可以发送 ETH 以换取相应的代币
sell：用户可以发送代币以换回 ETH

buy 函数

让我们编写 buy 函数的代码。我们首先需要检查消息中包含的 ETH 数量，并验证合约拥有足够的代币，以及消息中包含一些 ETH。如果合约拥有足够的代币，它会向用户发送相应数量的代币，并触发 Bought 事件。

请注意，如果在出错的情况下调用 require 函数，发送的 ETH 将被直接还原并退还给用户。

为简单起见，我们只需将 1 个代币换成 1 个 Wei。

1function buy() payable public {
2    uint256 amountTobuy = msg.value;
3    uint256 dexBalance = token.balanceOf(address(this));
4    require(amountTobuy > 0, "你需要发送一些 ETH");
5    require(amountTobuy <= dexBalance, "储备中的代币不足");
6    token.transfer(msg.sender, amountTobuy);
7    emit Bought(amountTobuy);
8}

如果购买成功，我们应该能在交易中看到两个事件：代币 Transfer 事件和 Bought 事件。

sell 函数

负责卖出的函数将首先要求用户事先调用 approve 函数来批准金额。要批准转账，用户需要调用由去中心化交易所 (DEX) 实例化的 ERC20Basic 代币。为此，首先需要调用去中心化交易所 (DEX) 合约的 token() 函数来检索 DEX 部署名为 token 的 ERC20Basic 合约的地址。然后，我们在会话中创建该合约的实例，并调用其 approve 函数。然后我们就可以调用 DEX 的 sell 函数，将我们的代币兑换回以太币。例如，该过程在交互式 Brownie 会话中显示如下：

1#### Python in interactive brownie console...
2
3# 部署 DEX
4dex = DEX.deploy({'from':account1})
5
6# 调用 buy 函数，用 ETH 兑换代币
7# 1e18 是 1 个以 wei 为单位的 ETH
8dex.buy({'from': account2, 1e18})
9
10# 获取 ERC20 代币的部署地址
11# 该代币在 DEX 合约创建时部署
12# dex.token() 返回代币的部署地址
13token = ERC20Basic.at(dex.token())
14
15# 调用代币的 approve 函数
16# 批准 DEX 地址为 spender
17# 以及允许它花费的代币数量
18token.approve(dex.address, 3e18, {'from':account2})
19
显示全部

然后当调用 sell 函数时，我们会检查从调用者地址到合约地址的转账是否成功，然后将以太币发送回调用者地址。

1function sell(uint256 amount) public {
2    require(amount > 0, "你至少需要卖出一些代币");
3    uint256 allowance = token.allowance(msg.sender, address(this));
4    require(allowance >= amount, "检查代币授权额度");
5    token.transferFrom(msg.sender, address(this), amount);
6    payable(msg.sender).transfer(amount);
7    emit Sold(amount);
8}

如果一切顺利，你应该能在交易中看到 2 个事件（一个 Transfer 事件和一个 Sold 事件），并且你的代币余额和 ETH 余额也会更新。

在本教程中，我们了解了如何检查 ERC-20 代币的余额和授权额度，以及如何使用接口调用 ERC20 智能合约的 Transfer 和 TransferFrom 函数。

完成交易后，我们有一个 JavaScript 教程，介绍如何等待并获取与你的合约进行的交易相关的详细信息opens in a new tab；只要你有 ABI，还可以参考另一个教程，学习解码由代币转账或任何其他事件生成的事件opens in a new tab。

下面是本教程的完整代码：

1pragma solidity ^0.8.0;
2
3interface IERC20 {
4
5    function totalSupply() external view returns (uint256);
6    function balanceOf(address account) external view returns (uint256);
7    function allowance(address owner, address spender) external view returns (uint256);
8
9    function transfer(address recipient, uint256 amount) external returns (bool);
10    function approve(address spender, uint256 amount) external returns (bool);
11    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);
12
13
14    event Transfer(address indexed from, address indexed to, uint256 value);
15    event Approval(address indexed owner, address indexed spender, uint256 value);
16}
17
18
19contract ERC20Basic is IERC20 {
20
21    string public constant name = "ERC20Basic";
22    string public constant symbol = "ERC";
23    uint8 public constant decimals = 18;
24
25
26    mapping(address => uint256) balances;
27
28    mapping(address => mapping (address => uint256)) allowed;
29
30    uint256 totalSupply_ = 10 ether;
31
32
33   constructor() {
34	balances[msg.sender] = totalSupply_;
35    }
36
37    function totalSupply() public override view returns (uint256) {
38	return totalSupply_;
39    }
40
41    function balanceOf(address tokenOwner) public override view returns (uint256) {
42        return balances[tokenOwner];
43    }
44
45    function transfer(address receiver, uint256 numTokens) public override returns (bool) {
46        require(numTokens <= balances[msg.sender]);
47        balances[msg.sender] = balances[msg.sender]-numTokens;
48        balances[receiver] = balances[receiver]+numTokens;
49        emit Transfer(msg.sender, receiver, numTokens);
50        return true;
51    }
52
53    function approve(address delegate, uint256 numTokens) public override returns (bool) {
54        allowed[msg.sender][delegate] = numTokens;
55        emit Approval(msg.sender, delegate, numTokens);
56        return true;
57    }
58
59    function allowance(address owner, address delegate) public override view returns (uint) {
60        return allowed[owner][delegate];
61    }
62
63    function transferFrom(address owner, address buyer, uint256 numTokens) public override returns (bool) {
64        require(numTokens <= balances[owner]);
65        require(numTokens <= allowed[owner][msg.sender]);
66
67        balances[owner] = balances[owner]-numTokens;
68        allowed[owner][msg.sender] = allowed[owner][msg.sender]-numTokens;
69        balances[buyer] = balances[buyer]+numTokens;
70        emit Transfer(owner, buyer, numTokens);
71        return true;
72    }
73}
74
75
76contract DEX {
77
78    event Bought(uint256 amount);
79    event Sold(uint256 amount);
80
81
82    IERC20 public token;
83
84    constructor() {
85        token = new ERC20Basic();
86    }
87
88    function buy() payable public {
89        uint256 amountTobuy = msg.value;
90        uint256 dexBalance = token.balanceOf(address(this));
91        require(amountTobuy > 0, "你需要发送一些 ETH");
92        require(amountTobuy <= dexBalance, "储备中的代币不足");
93        token.transfer(msg.sender, amountTobuy);
94        emit Bought(amountTobuy);
95    }
96
97    function sell(uint256 amount) public {
98        require(amount > 0, "你至少需要卖出一些代币");
99        uint256 allowance = token.allowance(msg.sender, address(this));
100        require(allowance >= amount, "检查代币授权额度");
101        token.transferFrom(msg.sender, address(this), amount);
102        payable(msg.sender).transfer(amount);
103        emit Sold(amount);
104    }
105
106}
显示全部

页面最后更新： 2025年8月21日

+11

通过 Solidity 智能合约转移和批准 ERC-20 代币

buy 函数

sell 函数

本教程对你有帮助吗？