SolidityスマートコントラクトによるERC-20トークンの転送と承認

スマートコントラクト

トークン

Solidity

ERC-20

中級

jdourlens

EthereumDev

2020年4月7日

10 分の読書

前回のチュートリアルでは、イーサリアムブロックチェーン上のSolidityで描かれたERC-20トークンの構造について学びました。この記事では、Solidity言語で書かれたトークンとやり取りするためのスマートコントラクトの使い方について説明します。

このスマートコントラクトのために、ユーザーがイーサを新しくデプロイされたERC-20トークンに交換できる、ダミーの分散型取引所を実際に作成します。

このチュートリアルでは、前のチュートリアルで書いたコードをベースとして使います。この分散型取引所(DEX)では、コントラクトのインスタンスをコンストラクタでインスタンス化し、以下の操作を実行します。

トークンをイーサ(ETH)に交換
イーサ(ETH)をトークンに交換

次のシンプルなERC20コードベースを追加することで、分散型取引所コードを開始します。

1pragma solidity ^0.8.0;
2
3interface IERC20 {
4
5    function totalSupply() external view returns (uint256);
6    function balanceOf(address account) external view returns (uint256);
7    function allowance(address owner, address spender) external view returns (uint256);
8
9    function transfer(address recipient, uint256 amount) external returns (bool);
10    function approve(address spender, uint256 amount) external returns (bool);
11    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);
12
13
14    event Transfer(address indexed from, address indexed to, uint256 value);
15    event Approval(address indexed owner, address indexed spender, uint256 value);
16}
17
18
19contract ERC20Basic is IERC20 {
20
21    string public constant name = "ERC20Basic";
22    string public constant symbol = "ERC";
23    uint8 public constant decimals = 18;
24
25
26    mapping(address => uint256) balances;
27
28    mapping(address => mapping (address => uint256)) allowed;
29
30    uint256 totalSupply_ = 10 ether;
31
32
33   constructor() {
34	balances[msg.sender] = totalSupply_;
35    }
36
37    function totalSupply() public override view returns (uint256) {
38	return totalSupply_;
39    }
40
41    function balanceOf(address tokenOwner) public override view returns (uint256) {
42        return balances[tokenOwner];
43    }
44
45    function transfer(address receiver, uint256 numTokens) public override returns (bool) {
46        require(numTokens <= balances[msg.sender]);
47        balances[msg.sender] = balances[msg.sender]-numTokens;
48        balances[receiver] = balances[receiver]+numTokens;
49        emit Transfer(msg.sender, receiver, numTokens);
50        return true;
51    }
52
53    function approve(address delegate, uint256 numTokens) public override returns (bool) {
54        allowed[msg.sender][delegate] = numTokens;
55        emit Approval(msg.sender, delegate, numTokens);
56        return true;
57    }
58
59    function allowance(address owner, address delegate) public override view returns (uint) {
60        return allowed[owner][delegate];
61    }
62
63    function transferFrom(address owner, address buyer, uint256 numTokens) public override returns (bool) {
64        require(numTokens <= balances[owner]);
65        require(numTokens <= allowed[owner][msg.sender]);
66
67        balances[owner] = balances[owner]-numTokens;
68        allowed[owner][msg.sender] = allowed[owner][msg.sender]-numTokens;
69        balances[buyer] = balances[buyer]+numTokens;
70        emit Transfer(owner, buyer, numTokens);
71        return true;
72    }
73}
74
75
すべて表示

次の新しい分散型取引所(DEX)スマートコントラクトは、ERC-20をデプロイし、供給されたすべてを取得します。

1contract DEX {
2
3    IERC20 public token;
4
5    event Bought(uint256 amount);
6    event Sold(uint256 amount);
7
8    constructor() {
9        token = new ERC20Basic();
10    }
11
12    function buy() payable public {
13        // TODO
14    }
15
16    function sell(uint256 amount) public {
17        // TODO
18    }
19
20}
すべて表示

これで分散型取引所(DEX)ができました。また、すべてのトークンリザーブが利用可能になりました。コントラクトには、次の2つの関数があります。

buy: ユーザーはイーサ(ETH)を送ってトークンに交換できます
sell: ユーザーはトークンを送信してイーサ(ETH)を取り戻すことができます

buy関数

buy関数をコーディングしてみましょう。まず、メッセージに含まれるイーサ(ETH)の量を確認し、コントラクトが十分なトークンを所有していること、そしてメッセージにイーサ(ETH)が含まれていることを検証する必要があります。コントラクトが十分なトークンを所有している場合、ユーザーにその分のトークンを送信し、Boughtイベントを発行します。

require関数の呼び出しがエラーだった場合に、送信されたイーサ(ETH)は直接元に戻され、ユーザーに返されることに注意してください。

ここではシンプルに、1トークンと1Weiを交換します。

1function buy() payable public {
2    uint256 amountTobuy = msg.value;
3    uint256 dexBalance = token.balanceOf(address(this));
4    require(amountTobuy > 0, "イーサを送信する必要があります");
5    require(amountTobuy <= dexBalance, "リザーブに十分なトークンがありません");
6    token.transfer(msg.sender, amountTobuy);
7    emit Bought(amountTobuy);
8}

購入が成功した場合、トランザクションにはトークンのTransferとBoughtの2つのイベントが表示されます。

sell関数

売却を担当する関数では、まずユーザーが事前にapprove関数を呼び出して、金額を承認しておく必要があります。転送を承認するには、ユーザーがDEXによってインスタンス化されたERC20Basicトークンコントラクトを呼び出す必要があります。これは、まずDEXコントラクトのtoken()関数を呼び出して、DEXがtokenというERC20Basicコントラクトをデプロイしたアドレスを取得することで実現できます。次に、セッション内にそのコントラクトのインスタンスを作成し、そのapprove関数を呼び出します。次に、DEXのsell関数を呼び出すことで、トークンをイーサ(ETH)に交換できます。例えば、インタラクティブ・ブラウニー(interactive brownie)セッションでは、次のようになります。

1#### インタラクティブ・ブラウニーコンソール内のPython...
2
3# DEXをデプロイする
4dex = DEX.deploy({'from':account1})
5
6# buy関数を呼び出してイーサをトークンにスワップする
7# 1e18はweiで表記した1イーサ
8dex.buy({'from': account2, 1e18})
9
10# DEXコントラクト作成時にデプロイされた
11# ERC20トークンのデプロイメントアドレスを取得する
12# dex.token()はデプロイされたトークンのアドレスを返す
13token = ERC20Basic.at(dex.token())
14
15# トークンのapprove関数を呼び出す
16# dexアドレスを使用者(spender)として承認し、
17# いくつのトークンを使用許可するかを指定する
18token.approve(dex.address, 3e18, {'from':account2})
19
すべて表示

その後、sell関数が呼び出されたときに、呼び出し元のアドレスからコントラクトアドレスへの転送が成功したかどうかを確認し、その後イーサ(ETH)を呼び出し元のアドレスに送信します。

1function sell(uint256 amount) public {
2    require(amount > 0, "少なくともいくらかのトークンを売る必要があります");
3    uint256 allowance = token.allowance(msg.sender, address(this));
4    require(allowance >= amount, "トークンの許可量を確認してください");
5    token.transferFrom(msg.sender, address(this), amount);
6    payable(msg.sender).transfer(amount);
7    emit Sold(amount);
8}

すべてがうまくいけば、トランザクションに2つのイベント (TransferとSold) が表示され、トークンの残高とイーサの残高が更新されるはずです。

このチュートリアルでは、ERC-20トークンの残高と許可量を確認する方法と、インターフェースを使用してERC20スマートコントラクトのTransferとTransferFromを呼び出す方法を学びました。

トランザクションを実行した後には、コントラクトに対して行われたトランザクションを待機し、詳細を取得する (opens in a new tab)ためのJavaScriptチュートリアルがあります。また、ABIをお持ちであれば、トークンの転送やその他のイベントによって生成されたイベントをデコードするチュートリアル (opens in a new tab)も利用できます。

チュートリアルの完全なコードは、次のようになります。

1pragma solidity ^0.8.0;
2
3interface IERC20 {
4
5    function totalSupply() external view returns (uint256);
6    function balanceOf(address account) external view returns (uint256);
7    function allowance(address owner, address spender) external view returns (uint256);
8
9    function transfer(address recipient, uint256 amount) external returns (bool);
10    function approve(address spender, uint256 amount) external returns (bool);
11    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);
12
13
14    event Transfer(address indexed from, address indexed to, uint256 value);
15    event Approval(address indexed owner, address indexed spender, uint256 value);
16}
17
18
19contract ERC20Basic is IERC20 {
20
21    string public constant name = "ERC20Basic";
22    string public constant symbol = "ERC";
23    uint8 public constant decimals = 18;
24
25
26    mapping(address => uint256) balances;
27
28    mapping(address => mapping (address => uint256)) allowed;
29
30    uint256 totalSupply_ = 10 ether;
31
32
33   constructor() {
34	balances[msg.sender] = totalSupply_;
35    }
36
37    function totalSupply() public override view returns (uint256) {
38	return totalSupply_;
39    }
40
41    function balanceOf(address tokenOwner) public override view returns (uint256) {
42        return balances[tokenOwner];
43    }
44
45    function transfer(address receiver, uint256 numTokens) public override returns (bool) {
46        require(numTokens <= balances[msg.sender]);
47        balances[msg.sender] = balances[msg.sender]-numTokens;
48        balances[receiver] = balances[receiver]+numTokens;
49        emit Transfer(msg.sender, receiver, numTokens);
50        return true;
51    }
52
53    function approve(address delegate, uint256 numTokens) public override returns (bool) {
54        allowed[msg.sender][delegate] = numTokens;
55        emit Approval(msg.sender, delegate, numTokens);
56        return true;
57    }
58
59    function allowance(address owner, address delegate) public override view returns (uint) {
60        return allowed[owner][delegate];
61    }
62
63    function transferFrom(address owner, address buyer, uint256 numTokens) public override returns (bool) {
64        require(numTokens <= balances[owner]);
65        require(numTokens <= allowed[owner][msg.sender]);
66
67        balances[owner] = balances[owner]-numTokens;
68        allowed[owner][msg.sender] = allowed[owner][msg.sender]-numTokens;
69        balances[buyer] = balances[buyer]+numTokens;
70        emit Transfer(owner, buyer, numTokens);
71        return true;
72    }
73}
74
75
76contract DEX {
77
78    event Bought(uint256 amount);
79    event Sold(uint256 amount);
80
81
82    IERC20 public token;
83
84    constructor() {
85        token = new ERC20Basic();
86    }
87
88    function buy() payable public {
89        uint256 amountTobuy = msg.value;
90        uint256 dexBalance = token.balanceOf(address(this));
91        require(amountTobuy > 0, "イーサを送信する必要があります");
92        require(amountTobuy <= dexBalance, "リザーブに十分なトークンがありません");
93        token.transfer(msg.sender, amountTobuy);
94        emit Bought(amountTobuy);
95    }
96
97    function sell(uint256 amount) public {
98        require(amount > 0, "少なくともいくらかのトークンを売る必要があります");
99        uint256 allowance = token.allowance(msg.sender, address(this));
100        require(allowance >= amount, "トークンの許可量を確認してください");
101        token.transferFrom(msg.sender, address(this), amount);
102        payable(msg.sender).transfer(amount);
103        emit Sold(amount);
104    }
105
106}
すべて表示

最終更新： 2025年8月21日

+11

SolidityスマートコントラクトによるERC-20トークンの転送と承認

buy関数

sell関数

このチュートリアルは役に立ちましたか?