ERC-1363 지불 가능 토큰 표준

pragma solidity ^0.8.0;

/**
 * @title ERC1363
 * @dev 단일 트랜잭션에서 `transfer` 또는 `transferFrom` 이후 수신자 컨트랙트에서 코드를 실행하거나, `approve` 이후 지출자 컨트랙트에서 코드를 실행하는 것을 지원하는 ERC-20 토큰용 확장 인터페이스입니다.
 */
interface ERC1363 is ERC20, ERC165 {
  /*
   * 참고: 이 인터페이스의 ERC-165 식별자는 0xb0202a11입니다.
   * 0xb0202a11 ===
   *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
   *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
   *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
   *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
   *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
   *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
   */

  /**
   * @dev 호출자의 계정에서 `to`로 `value`만큼의 토큰을 전송한 다음 `to`에서 `ERC1363Receiver::onTransferReceived`를 호출합니다.
   * @param to 토큰이 전송되는 주소입니다.
   * @param value 전송할 토큰의 양입니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function transferAndCall(address to, uint256 value) external returns (bool);

  /**
   * @dev 호출자의 계정에서 `to`로 `value`만큼의 토큰을 전송한 다음 `to`에서 `ERC1363Receiver::onTransferReceived`를 호출합니다.
   * @param to 토큰이 전송되는 주소입니다.
   * @param value 전송할 토큰의 양입니다.
   * @param data 지정된 형식이 없는 추가 데이터로, `to` 호출 시 전송됩니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

  /**
   * @dev 허용량(allowance) 메커니즘을 사용하여 `from`에서 `to`로 `value`만큼의 토큰을 전송한 다음 `to`에서 `ERC1363Receiver::onTransferReceived`를 호출합니다.
   * @param from 토큰을 보낼 주소입니다.
   * @param to 토큰이 전송되는 주소입니다.
   * @param value 전송할 토큰의 양입니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

  /**
   * @dev 허용량(allowance) 메커니즘을 사용하여 `from`에서 `to`로 `value`만큼의 토큰을 전송한 다음 `to`에서 `ERC1363Receiver::onTransferReceived`를 호출합니다.
   * @param from 토큰을 보낼 주소입니다.
   * @param to 토큰이 전송되는 주소입니다.
   * @param value 전송할 토큰의 양입니다.
   * @param data 지정된 형식이 없는 추가 데이터로, `to` 호출 시 전송됩니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

  /**
   * @dev 호출자의 토큰에 대해 `spender`의 허용량으로 `value`만큼의 토큰을 설정한 다음 `spender`에서 `ERC1363Spender::onApprovalReceived`를 호출합니다.
   * @param spender 자금을 지출할 주소입니다.
   * @param value 지출할 토큰의 양입니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function approveAndCall(address spender, uint256 value) external returns (bool);

  /**
   * @dev 호출자의 토큰에 대해 `spender`의 허용량으로 `value`만큼의 토큰을 설정한 다음 `spender`에서 `ERC1363Spender::onApprovalReceived`를 호출합니다.
   * @param spender 자금을 지출할 주소입니다.
   * @param value 지출할 토큰의 양입니다.
   * @param data 지정된 형식이 없는 추가 데이터로, `spender` 호출 시 전송됩니다.
   * @return 예외가 발생하지 않는 한 작업이 성공했음을 나타내는 부울 값입니다.
   */
  function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

interface ERC20 {
  event Transfer(address indexed from, address indexed to, uint256 value);
  event Approval(address indexed owner, address indexed spender, uint256 value);
  function transfer(address to, uint256 value) external returns (bool);
  function transferFrom(address from, address to, uint256 value) external returns (bool);
  function approve(address spender, uint256 value) external returns (bool);
  function totalSupply() external view returns (uint256);
  function balanceOf(address account) external view returns (uint256);
  function allowance(address owner, address spender) external view returns (uint256);
}

interface ERC165 {
  function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

/**
 * @title ERC1363Receiver
 * @dev ERC-1363 토큰 컨트랙트에서 `transferAndCall` 또는 `transferFromAndCall`을 지원하려는 모든 컨트랙트를 위한 인터페이스입니다.
 */
interface ERC1363Receiver {
  /**
   * @dev `operator`가 `from`에서 `ERC1363::transferAndCall` 또는 `ERC1363::transferFromAndCall`을 통해 이 컨트랙트로 ERC-1363 토큰을 전송할 때마다 이 함수가 호출됩니다.
   *
   * 참고: 전송을 수락하려면 이 함수는 반드시
   * `bytes4(keccak256("onTransferReceived(address,address,uint256,bytes)"))`
   * (즉, 0x88a7ca5c 또는 자체 함수 선택자)를 반환해야 합니다.
   *
   * @param operator `transferAndCall` 또는 `transferFromAndCall` 함수를 호출한 주소입니다.
   * @param from 토큰이 전송되는 출발지 주소입니다.
   * @param value 전송된 토큰의 양입니다.
   * @param data 지정된 형식이 없는 추가 데이터입니다.
   * @return 예외가 발생하지 않고 전송이 허용되는 경우 `bytes4(keccak256("onTransferReceived(address,address,uint256,bytes)"))`를 반환합니다.
   */
  function onTransferReceived(address operator, address from, uint256 value, bytes calldata data) external returns (bytes4);
}

/**
 * @title ERC1363Spender
 * @dev ERC-1363 토큰 컨트랙트에서 `approveAndCall`을 지원하려는 모든 컨트랙트를 위한 인터페이스입니다.
 */
interface ERC1363Spender {
  /**
   * @dev ERC-1363 토큰의 `owner`가 자신의 토큰을 지출하도록 `ERC1363::approveAndCall`을 통해 이 컨트랙트를 승인할 때마다 이 함수가 호출됩니다.
   *
   * 참고: 승인을 수락하려면 이 함수는 반드시
   * `bytes4(keccak256("onApprovalReceived(address,uint256,bytes)"))`
   * (즉, 0x7b04a2d0 또는 자체 함수 선택자)를 반환해야 합니다.
   *
   * @param owner `approveAndCall` 함수를 호출하고 이전에 토큰을 소유했던 주소입니다.
   * @param value 지출할 토큰의 양입니다.
   * @param data 지정된 형식이 없는 추가 데이터입니다.
   * @return 예외가 발생하지 않고 승인이 허용되는 경우 `bytes4(keccak256("onApprovalReceived(address,uint256,bytes)"))`를 반환합니다.
   */
  function onApprovalReceived(address owner, uint256 value, bytes calldata data) external returns (bytes4);
}