स्मार्ट अनुबंधों की संरचना

// Solidity उदाहरण
// अनुबंध के डेटा को प्रारंभ करता है, `owner` को सेट करता है
// अनुबंध निर्माता के पते पर।
constructor() public {
    // सभी स्मार्ट अनुबंध अपने कार्यों को ट्रिगर करने के लिए बाहरी लेन-देन पर निर्भर करते हैं।
    // `msg` एक वैश्विक चर है जिसमें दिए गए लेन-देन पर प्रासंगिक डेटा शामिल है,
    // जैसे कि प्रेषक का पता और लेन-देन में शामिल ETH मूल्य।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/units-and-global-variables.html#block-and-transaction-properties
    owner = msg.sender;
}

pragma solidity >=0.4.0 <=0.6.0;

contract ExampleDapp {
    string dapp_name; // स्थिति चर

    // अनुबंध तैनात होने पर कॉल किया जाता है और मूल्य को प्रारंभ करता है
    constructor() public {
        dapp_name = "My Example dapp";
    }

    // Get फ़ंक्शन
    function read_name() public view returns(string) {
        return dapp_name;
    }

    // Set फ़ंक्शन
    function update_name(string value) public {
        dapp_name = value;
    }
}

// सिमेंटिक वर्ज़निंग का उपयोग करके Solidity का संस्करण निर्दिष्ट करता है।
// अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/layout-of-source-files.html#pragma
pragma solidity ^0.5.10;

// `HelloWorld` नामक एक अनुबंध को परिभाषित करता है।
// एक अनुबंध कार्यों और डेटा (इसकी स्थिति) का एक संग्रह है।
// एक बार तैनात होने के बाद, एक अनुबंध इथेरियम ब्लॉकचेन पर एक विशिष्ट पते पर रहता है।
// अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/structure-of-a-contract.html
contract HelloWorld {

    // `string` प्रकार का एक स्थिति चर `message` घोषित करता है।
    // स्थिति चर वे चर होते हैं जिनके मूल्य स्थायी रूप से अनुबंध स्टोरेज में संग्रहीत होते हैं।
    // `public` कीवर्ड चरों को अनुबंध के बाहर से सुलभ बनाता है
    // और एक फ़ंक्शन बनाता है जिसे अन्य अनुबंध या क्लाइंट मूल्य तक पहुंचने के लिए कॉल कर सकते हैं।
    string public message;

    // कई क्लास-आधारित ऑब्जेक्ट-ओरिएंटेड भाषाओं के समान, एक कंस्ट्रक्टर
    // एक विशेष फ़ंक्शन है जो केवल अनुबंध निर्माण पर निष्पादित होता है।
    // कंस्ट्रक्टर का उपयोग अनुबंध के डेटा को प्रारंभ करने के लिए किया जाता है।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#constructors
    constructor(string memory initMessage) public {
        // एक स्ट्रिंग तर्क `initMessage` स्वीकार करता है और मूल्य को
        // अनुबंध के `message` स्टोरेज चर में सेट करता है)।
        message = initMessage;
    }

    // एक सार्वजनिक फ़ंक्शन जो एक स्ट्रिंग तर्क स्वीकार करता है
    // और `message` स्टोरेज चर को अपडेट करता है।
    function update(string memory newMessage) public {
        message = newMessage;
    }
}

pragma solidity ^0.5.10;

contract Token {
    // एक पता ईमेल पते के तुलनीय है - इसका उपयोग इथेरियम पर किसी खाते की पहचान करने के लिए किया जाता है।
    // पते एक स्मार्ट अनुबंध या बाहरी (उपयोगकर्ता) खातों का प्रतिनिधित्व कर सकते हैं।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/types.html#address
    address public owner;

    // एक `mapping` अनिवार्य रूप से एक हैश टेबल डेटा संरचना है।
    // यह `mapping` एक पते (टोकन धारक) को एक अहस्ताक्षरित पूर्णांक (टोकन बैलेंस) प्रदान करता है।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/types.html#mapping-types
    mapping (address => uint) public balances;

    // घटनाएँ ब्लॉकचेन पर गतिविधि की लॉगिंग की अनुमति देती हैं।
    // इथेरियम क्लाइंट अनुबंध की स्थिति में बदलावों पर प्रतिक्रिया देने के लिए घटनाओं को सुन सकते हैं।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#events
    event Transfer(address from, address to, uint amount);

    // अनुबंध के डेटा को प्रारंभ करता है, `owner` को सेट करता है
    // अनुबंध निर्माता के पते पर।
    constructor() public {
        // सभी स्मार्ट अनुबंध अपने कार्यों को ट्रिगर करने के लिए बाहरी लेन-देन पर निर्भर करते हैं।
        // `msg` एक वैश्विक चर है जिसमें दिए गए लेन-देन पर प्रासंगिक डेटा शामिल है,
        // जैसे कि प्रेषक का पता और लेन-देन में शामिल ETH मूल्य।
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/units-and-global-variables.html#block-and-transaction-properties
        owner = msg.sender;
    }

    // नए टोकन की एक मात्रा बनाता है और उन्हें एक पते पर भेजता है।
    function mint(address receiver, uint amount) public {
        // `require` एक नियंत्रण संरचना है जिसका उपयोग कुछ शर्तों को लागू करने के लिए किया जाता है।
        // यदि एक `require` कथन `false` का मूल्यांकन करता है, तो एक अपवाद ट्रिगर होता है,
        // जो वर्तमान कॉल के दौरान स्थिति में किए गए सभी परिवर्तनों को वापस कर देता है।
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/control-structures.html#error-handling-assert-require-revert-and-exceptions

        // केवल अनुबंध स्वामी ही इस फ़ंक्शन को कॉल कर सकता है
        require(msg.sender == owner, "You are not the owner.");

        // टोकन की अधिकतम मात्रा लागू करता है
        require(amount < 1e60, "Maximum issuance exceeded");

        // `receiver` के बैलेंस को `amount` से बढ़ाता है
        balances[receiver] += amount;
    }

    // किसी भी कॉलर से एक पते पर मौजूदा टोकन की एक मात्रा भेजता है।
    function transfer(address receiver, uint amount) public {
        // भेजने के लिए प्रेषक के पास पर्याप्त टोकन होने चाहिए
        require(amount <= balances[msg.sender], "Insufficient balance.");

        // दोनों पतों के टोकन बैलेंस को समायोजित करता है
        balances[msg.sender] -= amount;
        balances[receiver] += amount;

        // पहले परिभाषित घटना का उत्सर्जन करता है
        emit Transfer(msg.sender, receiver, amount);
    }
}

pragma solidity ^0.5.10;

// अन्य फ़ाइलों से प्रतीकों को वर्तमान अनुबंध में आयात करता है।
// इस मामले में, OpenZeppelin से सहायक अनुबंधों की एक श्रृंखला।
// अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/layout-of-source-files.html#importing-other-source-files

import "../node_modules/@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "../node_modules/@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import "../node_modules/@openzeppelin/contracts/introspection/ERC165.sol";
import "../node_modules/@openzeppelin/contracts/math/SafeMath.sol";

// `is` कीवर्ड का उपयोग बाहरी अनुबंधों से कार्यों और कीवर्ड को इनहेरिट करने के लिए किया जाता है।
// इस मामले में, `CryptoPizza` `IERC721` और `ERC165` अनुबंधों से इनहेरिट करता है।
// अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#inheritance
contract CryptoPizza is IERC721, ERC165 {
    // अंकगणितीय कार्यों को सुरक्षित रूप से करने के लिए OpenZeppelin की SafeMath लाइब्रेरी का उपयोग करता है।
    // अधिक जानें: https://docs.openzeppelin.com/contracts/2.x/api/math#SafeMath
    using SafeMath for uint256;

    // Solidity में निरंतर स्थिति चर अन्य भाषाओं के समान हैं
    // लेकिन आपको एक ऐसे व्यंजक से असाइन करना होगा जो संकलन समय पर निरंतर हो।
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#constant-state-variables
    uint256 constant dnaDigits = 10;
    uint256 constant dnaModulus = 10 ** dnaDigits;
    bytes4 private constant _ERC721_RECEIVED = 0x150b7a02;

    // Struct प्रकार आपको अपना स्वयं का प्रकार परिभाषित करने देते हैं
    // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/types.html#structs
    struct Pizza {
        string name;
        uint256 dna;
    }

    // Pizza structs का एक खाली ऐरे बनाता है
    Pizza[] public pizzas;

    // पिज्जा ID से उसके मालिक के पते तक मैपिंग
    mapping(uint256 => address) public pizzaToOwner;

    // मालिक के पते से स्वामित्व वाले टोकन की संख्या तक मैपिंग
    mapping(address => uint256) public ownerPizzaCount;

    // टोकन ID से स्वीकृत पते तक मैपिंग
    mapping(uint256 => address) pizzaApprovals;

    // आप मैपिंग को नेस्ट कर सकते हैं, यह उदाहरण मालिक को ऑपरेटर की स्वीकृतियों से मैप करता है
    mapping(address => mapping(address => bool)) private operatorApprovals;

    // स्ट्रिंग (नाम) और DNA से एक यादृच्छिक पिज्जा बनाने के लिए आंतरिक फ़ंक्शन
    function _createPizza(string memory _name, uint256 _dna)
        // `internal` कीवर्ड का अर्थ है कि यह फ़ंक्शन केवल
        // इस अनुबंध और इस अनुबंध से प्राप्त अनुबंधों के भीतर दिखाई देता है
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#visibility-and-getters
        internal
        // `isUnique` एक फ़ंक्शन संशोधक है जो जांचता है कि क्या पिज्जा पहले से मौजूद है
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/structure-of-a-contract.html#function-modifiers
        isUnique(_name, _dna)
    {
        // पिज्जा के ऐरे में पिज्जा जोड़ता है और id प्राप्त करता है
        uint256 id = SafeMath.sub(pizzas.push(Pizza(_name, _dna)), 1);

        // जांचता है कि पिज्जा का मालिक वर्तमान उपयोगकर्ता के समान है
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/control-structures.html#error-handling-assert-require-revert-and-exceptions

        // ध्यान दें कि address(0) शून्य पता है,
        // जो यह दर्शाता है कि pizza[id] अभी तक किसी विशेष उपयोगकर्ता को आवंटित नहीं किया गया है।

        assert(pizzaToOwner[id] == address(0));

        // पिज्जा को मालिक से मैप करता है
        pizzaToOwner[id] = msg.sender;
        ownerPizzaCount[msg.sender] = SafeMath.add(
            ownerPizzaCount[msg.sender],
            1
        );
    }

    // स्ट्रिंग (नाम) से एक यादृच्छिक पिज्जा बनाता है
    function createRandomPizza(string memory _name) public {
        uint256 randDna = generateRandomDna(_name, msg.sender);
        _createPizza(_name, randDna);
    }

    // स्ट्रिंग (नाम) और मालिक (निर्माता) के पते से यादृच्छिक DNA उत्पन्न करता है
    function generateRandomDna(string memory _str, address _owner)
        public
        // `pure` के रूप में चिह्नित फ़ंक्शन स्थिति को न पढ़ने या संशोधित न करने का वादा करते हैं
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#pure-functions
        pure
        returns (uint256)
    {
        // स्ट्रिंग (नाम) + पते (मालिक) से यादृच्छिक uint उत्पन्न करता है
        uint256 rand = uint256(keccak256(abi.encodePacked(_str))) +
            uint256(_owner);
        rand = rand % dnaModulus;
        return rand;
    }

    // मालिक द्वारा पाए गए पिज्जा का ऐरे लौटाता है
    function getPizzasByOwner(address _owner)
        public
        // `view` के रूप में चिह्नित फ़ंक्शन स्थिति को संशोधित न करने का वादा करते हैं
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#view-functions
        view
        returns (uint256[] memory)
    {
        // `memory` स्टोरेज स्थान का उपयोग मूल्यों को केवल
        // इस फ़ंक्शन कॉल के जीवनचक्र के लिए संग्रहीत करने के लिए करता है।
        // अधिक जानें: https://solidity.readthedocs.io/en/v0.5.10/introduction-to-smart-contracts.html#storage-memory-and-the-stack
        uint256[] memory result = new uint256[](ownerPizzaCount[_owner]);
        uint256 counter = 0;
        for (uint256 i = 0; i < pizzas.length; i++) {
            if (pizzaToOwner[i] == _owner) {
                result[counter] = i;
                counter++;
            }
        }
        return result;
    }

    // पिज्जा और स्वामित्व को अन्य पते पर स्थानांतरित करता है
    function transferFrom(address _from, address _to, uint256 _pizzaId) public {
        require(_from != address(0) && _to != address(0), "Invalid address.");
        require(_exists(_pizzaId), "Pizza does not exist.");
        require(_from != _to, "Cannot transfer to the same address.");
        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");

        ownerPizzaCount[_to] = SafeMath.add(ownerPizzaCount[_to], 1);
        ownerPizzaCount[_from] = SafeMath.sub(ownerPizzaCount[_from], 1);
        pizzaToOwner[_pizzaId] = _to;

        // आयातित IERC721 अनुबंध में परिभाषित घटना का उत्सर्जन करता है
        emit Transfer(_from, _to, _pizzaId);
        _clearApproval(_to, _pizzaId);
    }

    /**
     * दिए गए टोकन ID के स्वामित्व को सुरक्षित रूप से किसी अन्य पते पर स्थानांतरित करता है
     * यदि लक्ष्य पता एक अनुबंध है, तो इसे `onERC721Received` लागू करना चाहिए,
     * जिसे सुरक्षित स्थानांतरण पर कॉल किया जाता है, और जादुई मूल्य
     * `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))` लौटाना चाहिए;
     * अन्यथा, स्थानांतरण वापस कर दिया जाता है।
    */
    function safeTransferFrom(address from, address to, uint256 pizzaId)
        public
    {
        // solium-disable-next-line arg-overflow
        this.safeTransferFrom(from, to, pizzaId, "");
    }

    /**
     * दिए गए टोकन ID के स्वामित्व को सुरक्षित रूप से किसी अन्य पते पर स्थानांतरित करता है
     * यदि लक्ष्य पता एक अनुबंध है, तो इसे `onERC721Received` लागू करना चाहिए,
     * जिसे सुरक्षित स्थानांतरण पर कॉल किया जाता है, और जादुई मूल्य
     * `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))` लौटाना चाहिए;
     * अन्यथा, स्थानांतरण वापस कर दिया जाता है।
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 pizzaId,
        bytes memory _data
    ) public {
        this.transferFrom(from, to, pizzaId);
        require(_checkOnERC721Received(from, to, pizzaId, _data), "Must implement onERC721Received.");
    }

    /**
     * लक्ष्य पते पर `onERC721Received` को लागू करने के लिए आंतरिक फ़ंक्शन
     * यदि लक्ष्य पता एक अनुबंध नहीं है तो कॉल निष्पादित नहीं की जाती है
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 pizzaId,
        bytes memory _data
    ) internal returns (bool) {
        if (!isContract(to)) {
            return true;
        }

        bytes4 retval = IERC721Receiver(to).onERC721Received(
            msg.sender,
            from,
            pizzaId,
            _data
        );
        return (retval == _ERC721_RECEIVED);
    }

    // पिज्जा को बर्न करता है - टोकन को पूरी तरह से नष्ट कर देता है
    // `external` फ़ंक्शन संशोधक का अर्थ है कि यह फ़ंक्शन
    // अनुबंध इंटरफ़ेस का हिस्सा है और अन्य अनुबंध इसे कॉल कर सकते हैं
    function burn(uint256 _pizzaId) external {
        require(msg.sender != address(0), "Invalid address.");
        require(_exists(_pizzaId), "Pizza does not exist.");
        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");

        ownerPizzaCount[msg.sender] = SafeMath.sub(
            ownerPizzaCount[msg.sender],
            1
        );
        pizzaToOwner[_pizzaId] = address(0);
    }

    // पते के अनुसार पिज्जा की संख्या लौटाता है
    function balanceOf(address _owner) public view returns (uint256 _balance) {
        return ownerPizzaCount[_owner];
    }

    // id द्वारा पाए गए पिज्जा का मालिक लौटाता है
    function ownerOf(uint256 _pizzaId) public view returns (address _owner) {
        address owner = pizzaToOwner[_pizzaId];
        require(owner != address(0), "Invalid Pizza ID.");
        return owner;
    }

    // पिज्जा के स्वामित्व को स्थानांतरित करने के लिए अन्य पते को स्वीकृति देता है
    function approve(address _to, uint256 _pizzaId) public {
        require(msg.sender == pizzaToOwner[_pizzaId], "Must be the Pizza owner.");
        pizzaApprovals[_pizzaId] = _to;
        emit Approval(msg.sender, _to, _pizzaId);
    }

    // विशिष्ट पिज्जा के लिए स्वीकृत पता लौटाता है
    function getApproved(uint256 _pizzaId)
        public
        view
        returns (address operator)
    {
        require(_exists(_pizzaId), "Pizza does not exist.");
        return pizzaApprovals[_pizzaId];
    }

    /**
     * दिए गए टोकन ID की वर्तमान स्वीकृति को साफ़ करने के लिए निजी फ़ंक्शन
     * यदि दिया गया पता वास्तव में टोकन का मालिक नहीं है तो वापस कर देता है
     */
    function _clearApproval(address owner, uint256 _pizzaId) private {
        require(pizzaToOwner[_pizzaId] == owner, "Must be pizza owner.");
        require(_exists(_pizzaId), "Pizza does not exist.");
        if (pizzaApprovals[_pizzaId] != address(0)) {
            pizzaApprovals[_pizzaId] = address(0);
        }
    }

    /*
     * किसी दिए गए ऑपरेटर की स्वीकृति को सेट या अनसेट करता है
     * एक ऑपरेटर को प्रेषक की ओर से उनके सभी टोकन स्थानांतरित करने की अनुमति है
     */
    function setApprovalForAll(address to, bool approved) public {
        require(to != msg.sender, "Cannot approve own address");
        operatorApprovals[msg.sender][to] = approved;
        emit ApprovalForAll(msg.sender, to, approved);
    }

    // बताता है कि क्या किसी दिए गए मालिक द्वारा ऑपरेटर को स्वीकृति दी गई है
    function isApprovedForAll(address owner, address operator)
        public
        view
        returns (bool)
    {
        return operatorApprovals[owner][operator];
    }

    // पिज्जा का स्वामित्व लेता है - केवल स्वीकृत उपयोगकर्ताओं के लिए
    function takeOwnership(uint256 _pizzaId) public {
        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");
        address owner = this.ownerOf(_pizzaId);
        this.transferFrom(owner, msg.sender, _pizzaId);
    }

    // जांचता है कि क्या पिज्जा मौजूद है
    function _exists(uint256 pizzaId) internal view returns (bool) {
        address owner = pizzaToOwner[pizzaId];
        return owner != address(0);
    }

    // जांचता है कि क्या पता मालिक है या पिज्जा स्थानांतरित करने के लिए स्वीकृत है
    function _isApprovedOrOwner(address spender, uint256 pizzaId)
        internal
        view
        returns (bool)
    {
        address owner = pizzaToOwner[pizzaId];
        // solium जांच को अक्षम करें क्योंकि
        // https://github.com/duaraghav8/Solium/issues/175
        // solium-disable-next-line operator-whitespace
        return (spender == owner ||
            this.getApproved(pizzaId) == spender ||
            this.isApprovedForAll(owner, spender));
    }

    // जांचें कि क्या पिज्जा अद्वितीय है और अभी तक मौजूद नहीं है
    modifier isUnique(string memory _name, uint256 _dna) {
        bool result = true;
        for (uint256 i = 0; i < pizzas.length; i++) {
            if (
                keccak256(abi.encodePacked(pizzas[i].name)) ==
                keccak256(abi.encodePacked(_name)) &&
                pizzas[i].dna == _dna
            ) {
                result = false;
            }
        }
        require(result, "Pizza with such name already exists.");
        _;
    }

    // लौटाता है कि क्या लक्ष्य पता एक अनुबंध है
    function isContract(address account) internal view returns (bool) {
        uint256 size;
        // वर्तमान में यह जांचने का कोई बेहतर तरीका नहीं है कि किसी पते में कोई अनुबंध है या नहीं
        // बजाय इसके कि उस पते पर कोड के आकार की जांच की जाए।
        // देखें https://ethereum.stackexchange.com/a/14016/36603
        // यह कैसे काम करता है, इसके बारे में अधिक जानकारी के लिए।
        // TODO Serenity रिलीज़ से पहले इसे फिर से जांचें, क्योंकि तब सभी पते
        // अनुबंध होंगे।
        // solium-disable-next-line security/no-inline-assembly
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }
}