スマートコントラクトの解剖学

1// Solidityの例
2contract SimpleStorage {
3    uint storedData; // 状態変数
4    // ...
5}
コピー

1# Vyperの例
2storedData: int128
コピー

1// Solidityの例
2function update_name(string value) public {
3    dapp_name = value;
4}
コピー

1// Solidityの例
2function balanceOf(address _owner) public view returns (uint256 _balance) {
3    return ownerPizzaCount[_owner];
4}
コピー

1dappName: public(string)
2
3@view
4@public
5def readName() -> string:
6  return dappName
コピー

1// Solidityの例
2// コントラクトのデータを初期化し、`owner`を
3// コントラクト作成者のアドレスに設定します。
4constructor() public {
5    // すべてのスマートコントラクトは、その関数をトリガーするために外部トランザクションに依存します。
6    // `msg`は、送信者のアドレスやトランザクションに含まれるETHの量など、
7    // 特定のトランザクションに関する関連データを含むグローバル変数です。
8    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/units-and-global-variables.html#block-and-transaction-properties
9    owner = msg.sender;
10}
すべて表示
コピー

1# Vyperの例
2
3@external
4def __init__(_beneficiary: address, _bidding_time: uint256):
5    self.beneficiary = _beneficiary
6    self.auctionStart = block.timestamp
7    self.auctionEnd = self.auctionStart + _bidding_time
コピー

1pragma solidity >=0.4.0 <=0.6.0;
2
3contract ExampleDapp {
4    string dapp_name; // 状態変数
5
6    // コントラクトがデプロイされたときに呼び出され、値を初期化します
7    constructor() public {
8        dapp_name = "My Example dapp";
9    }
10
11    // Get関数
12    function read_name() public view returns(string) {
13        return dapp_name;
14    }
15
16    // Set関数
17    function update_name(string value) public {
18        dapp_name = value;
19    }
20}
すべて表示
コピー

1// セマンティックバージョニングを使用して、Solidityのバージョンを指定します。
2// 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/layout-of-source-files.html#pragma
3pragma solidity ^0.5.10;
4
5// `HelloWorld`という名前のコントラクトを定義します。
6// コントラクトは、関数とデータ(その状態)のコレクションです。
7// デプロイされると、コントラクトはイーサリアムブロックチェーン上の特定のアドレスに配置されます。
8// 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/structure-of-a-contract.html
9contract HelloWorld {
10
11    // `string`型の状態変数`message`を宣言します。
12    // 状態変数は、その値がコントラクトのストレージに永続的に保存される変数です。
13    // `public`キーワードは、変数をコントラクトの外部からアクセス可能にし、
14    // 他のコントラクトやクライアントが値をアクセスするために呼び出すことができる関数を作成します。
15    string public message;
16
17    // 多くのクラスベースのオブジェクト指向言語と同様に、コンストラクタは
18    // コントラクトの作成時にのみ実行される特別な関数です。
19    // コンストラクタは、コントラクトのデータを初期化するために使用されます。
20    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#constructors
21    constructor(string memory initMessage) public {
22        // 文字列引数`initMessage`を受け入れ、その値を
23        // コントラクトの`message`ストレージ変数に設定します)。
24        message = initMessage;
25    }
26
27    // 文字列引数を受け入れ、
28    // `message`ストレージ変数を更新するpublic関数です。
29    function update(string memory newMessage) public {
30        message = newMessage;
31    }
32}
すべて表示
コピー

1pragma solidity ^0.5.10;
2
3contract Token {
4    // `address`はEメールアドレスに似ています - イーサリアム上のアカウントを識別するために使用されます。
5    // アドレスは、スマートコントラクトまたは外部(ユーザー)アカウントを表すことができます。
6    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/types.html#address
7    address public owner;
8
9    // `mapping`は、本質的にハッシュテーブルのデータ構造です。
10    // この`mapping`は、符号なし整数(トークン残高)をアドレス(トークン保有者)に割り当てます。
11    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/types.html#mapping-types
12    mapping (address => uint) balances;
13
14    // イベントにより、ブロックチェーン上のアクティビティをログに記録できます。
15    // イーサリアムクライアントは、コントラクトの状態変更に反応するためにイベントをリッスンできます。
16    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#events
17    event Transfer(address from, address to, uint amount);
18
19    // コントラクトのデータを初期化し、`owner`を
20    // コントラクト作成者のアドレスに設定します。
21    constructor() public {
22        // すべてのスマートコントラクトは、その関数をトリガーするために外部トランザクションに依存します。
23        // `msg`は、送信者のアドレスやトランザクションに含まれるETHの量など、
24        // 特定のトランザクションに関する関連データを含むグローバル変数です。
25        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/units-and-global-variables.html#block-and-transaction-properties
26        owner = msg.sender;
27    }
28
29    // 新しいトークンを作成し、アドレスに送信します。
30    function mint(address receiver, uint amount) public {
31        // `require`は、特定の条件を強制するために使用される制御構造です。
32        // `require`ステートメントが`false`と評価された場合、例外がトリガーされ、
33        // 現在の呼び出し中に行われた状態へのすべての変更が元に戻されます。
34        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/control-structures.html#error-handling-assert-require-revert-and-exceptions
35
36        // コントラクトのオーナーのみがこの関数を呼び出すことができます
37        require(msg.sender == owner, "You are not the owner.");
38
39        // トークンの最大量を強制します
40        require(amount < 1e60, "Maximum issuance exceeded");
41
42        // `receiver`の残高を`amount`だけ増やします
43        balances[receiver] += amount;
44    }
45
46    // 任意の呼び出し元からアドレスに既存のトークンを送信します。
47    function transfer(address receiver, uint amount) public {
48        // 送信者は送信するのに十分なトークンを持っている必要があります
49        require(amount <= balances[msg.sender], "Insufficient balance.");
50
51        // 2つのアドレスのトークン残高を調整します
52        balances[msg.sender] -= amount;
53        balances[receiver] += amount;
54
55        // 先に定義されたイベントを発行します
56        emit Transfer(msg.sender, receiver, amount);
57    }
58}
すべて表示
コピー

1pragma solidity ^0.5.10;
2
3// 他のファイルから現在のコントラクトにシンボルをインポートします。
4// このケースでは、OpenZeppelinの一連のヘルパーコントラクトです。
5// 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/layout-of-source-files.html#importing-other-source-files
6
7import "../node_modules/@openzeppelin/contracts/token/ERC721/IERC721.sol";
8import "../node_modules/@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
9import "../node_modules/@openzeppelin/contracts/introspection/ERC165.sol";
10import "../node_modules/@openzeppelin/contracts/math/SafeMath.sol";
11
12// `is`キーワードは、外部コントラクトから関数とキーワードを継承するために使用されます。
13// このケースでは、`CryptoPizza`は`IERC721`と`ERC165`コントラクトから継承します。
14// 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#inheritance
15contract CryptoPizza is IERC721, ERC165 {
16    // OpenZeppelinのSafeMathライブラリを使用して、算術演算を安全に実行します。
17    // 詳細はこちら: https://docs.openzeppelin.com/contracts/2.x/api/math#SafeMath
18    using SafeMath for uint256;
19
20    // Solidityの定数状態変数は他の言語に似ていますが、
21    // コンパイル時に定数である式から代入する必要があります。
22    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#constant-state-variables
23    uint256 constant dnaDigits = 10;
24    uint256 constant dnaModulus = 10 ** dnaDigits;
25    bytes4 private constant _ERC721_RECEIVED = 0x150b7a02;
26
27    // Struct型を使用すると、独自の型を定義できます
28    // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/types.html#structs
29    struct Pizza {
30        string name;
31        uint256 dna;
32    }
33
34    // Pizza構造体の空の配列を作成します
35    Pizza[] public pizzas;
36
37    // ピザIDからそのオーナーのアドレスへのマッピング
38    mapping(uint256 => address) public pizzaToOwner;
39
40    // オーナーのアドレスから所有トークン数へのマッピング
41    mapping(address => uint256) public ownerPizzaCount;
42
43    // トークンIDから承認済みアドレスへのマッピング
44    mapping(uint256 => address) pizzaApprovals;
45
46    // マッピングをネストすることができます。この例では、オーナーをオペレーターの承認にマッピングします
47    mapping(address => mapping(address => bool)) private operatorApprovals;
48
49    // 文字列(名前)とDNAからランダムなピザを作成する内部関数
50    function _createPizza(string memory _name, uint256 _dna)
51        // `internal`キーワードは、この関数がこのコントラクトおよび
52        // このコントラクトを派生するコントラクト内でのみ参照可能であることを意味します
53        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#visibility-and-getters
54        internal
55        // `isUnique`は、ピザがすでに存在するかどうかをチェックする関数修飾子です
56        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/structure-of-a-contract.html#function-modifiers
57        isUnique(_name, _dna)
58    {
59        // ピザをピザ配列に追加し、IDを取得します
60        uint256 id = SafeMath.sub(pizzas.push(Pizza(_name, _dna)), 1);
61
62        // ピザのオーナーが現在のユーザーと同じであることを確認します
63        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/control-structures.html#error-handling-assert-require-revert-and-exceptions
64
65        // address(0)はゼロアドレスであり、
66        // pizza[id]がまだ特定のユーザーに割り当てられていないことを示します。
67
68        assert(pizzaToOwner[id] == address(0));
69
70        // ピザをオーナーにマッピングします
71        pizzaToOwner[id] = msg.sender;
72        ownerPizzaCount[msg.sender] = SafeMath.add(
73            ownerPizzaCount[msg.sender],
74            1
75        );
76    }
77
78    // 文字列(名前)からランダムなピザを作成します
79    function createRandomPizza(string memory _name) public {
80        uint256 randDna = generateRandomDna(_name, msg.sender);
81        _createPizza(_name, randDna);
82    }
83
84    // 文字列(名前)とオーナーのアドレス(作成者)からランダムなDNAを生成します
85    function generateRandomDna(string memory _str, address _owner)
86        public
87        // `pure`とマークされた関数は、状態の読み取りや変更を行わないことを約束します
88        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#pure-functions
89        pure
90        returns (uint256)
91    {
92        // 文字列(名前) + アドレス(オーナー)からランダムなuintを生成します
93        uint256 rand = uint256(keccak256(abi.encodePacked(_str))) +
94            uint256(_owner);
95        rand = rand % dnaModulus;
96        return rand;
97    }
98
99    // オーナーによって見つかったピザの配列を返します
100    function getPizzasByOwner(address _owner)
101        public
102        // `view`とマークされた関数は、状態を変更しないことを約束します
103        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/contracts.html#view-functions
104        view
105        returns (uint256[] memory)
106    {
107        // `memory`ストレージの場所を使用して、この関数呼び出しの
108        // ライフサイクル中のみ値を格納します。
109        // 詳細はこちら: https://solidity.readthedocs.io/en/v0.5.10/introduction-to-smart-contracts.html#storage-memory-and-the-stack
110        uint256[] memory result = new uint256[](ownerPizzaCount[_owner]);
111        uint256 counter = 0;
112        for (uint256 i = 0; i < pizzas.length; i++) {
113            if (pizzaToOwner[i] == _owner) {
114                result[counter] = i;
115                counter++;
116            }
117        }
118        return result;
119    }
120
121    // ピザと所有権を他のアドレスに転送します
122    function transferFrom(address _from, address _to, uint256 _pizzaId) public {
123        require(_from != address(0) && _to != address(0), "Invalid address.");
124        require(_exists(_pizzaId), "Pizza does not exist.");
125        require(_from != _to, "Cannot transfer to the same address.");
126        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");
127
128        ownerPizzaCount[_to] = SafeMath.add(ownerPizzaCount[_to], 1);
129        ownerPizzaCount[_from] = SafeMath.sub(ownerPizzaCount[_from], 1);
130        pizzaToOwner[_pizzaId] = _to;
131
132        // インポートされたIERC721コントラクトで定義されたイベントを発行します
133        emit Transfer(_from, _to, _pizzaId);
134        _clearApproval(_to, _pizzaId);
135    }
136
137    /**
138     * 指定されたトークンIDの所有権を別のアドレスに安全に転送します
139     * ターゲットアドレスがコントラクトの場合、`onERC721Received`を実装する必要があります。
140     * これは安全な転送時に呼び出され、マジック値を返します
141     * `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`;
142     * そうでない場合、転送は取り消されます。
143    */
144    function safeTransferFrom(address from, address to, uint256 pizzaId)
145        public
146    {
147        // solium-disable-next-line arg-overflow
148        this.safeTransferFrom(from, to, pizzaId, "");
149    }
150
151    /**
152     * 指定されたトークンIDの所有権を別のアドレスに安全に転送します
153     * ターゲットアドレスがコントラクトの場合、`onERC721Received`を実装する必要があります。
154     * これは安全な転送時に呼び出され、マジック値を返します
155     * `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`;
156     * そうでない場合、転送は取り消されます。
157     */
158    function safeTransferFrom(
159        address from,
160        address to,
161        uint256 pizzaId,
162        bytes memory _data
163    ) public {
164        this.transferFrom(from, to, pizzaId);
165        require(_checkOnERC721Received(from, to, pizzaId, _data), "Must implement onERC721Received.");
166    }
167
168    /**
169     * ターゲットアドレスで`onERC721Received`を呼び出す内部関数
170     * ターゲットアドレスがコントラクトでない場合、呼び出しは実行されません
171     */
172    function _checkOnERC721Received(
173        address from,
174        address to,
175        uint256 pizzaId,
176        bytes memory _data
177    ) internal returns (bool) {
178        if (!isContract(to)) {
179            return true;
180        }
181
182        bytes4 retval = IERC721Receiver(to).onERC721Received(
183            msg.sender,
184            from,
185            pizzaId,
186            _data
187        );
188        return (retval == _ERC721_RECEIVED);
189    }
190
191    // ピザを燃やす - トークンを完全に破壊する
192    // `external`関数修飾子は、この関数が
193    // コントラクトインターフェースの一部であり、他のコントラクトがそれを呼び出すことができることを意味します
194    function burn(uint256 _pizzaId) external {
195        require(msg.sender != address(0), "Invalid address.");
196        require(_exists(_pizzaId), "Pizza does not exist.");
197        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");
198
199        ownerPizzaCount[msg.sender] = SafeMath.sub(
200            ownerPizzaCount[msg.sender],
201            1
202        );
203        pizzaToOwner[_pizzaId] = address(0);
204    }
205
206    // アドレスごとのピザの数を返します
207    function balanceOf(address _owner) public view returns (uint256 _balance) {
208        return ownerPizzaCount[_owner];
209    }
210
211    // IDで見つかったピザのオーナーを返します
212    function ownerOf(uint256 _pizzaId) public view returns (address _owner) {
213        address owner = pizzaToOwner[_pizzaId];
214        require(owner != address(0), "Invalid Pizza ID.");
215        return owner;
216    }
217
218    // 他のアドレスがピザの所有権を転送することを承認します
219    function approve(address _to, uint256 _pizzaId) public {
220        require(msg.sender == pizzaToOwner[_pizzaId], "Must be the Pizza owner.");
221        pizzaApprovals[_pizzaId] = _to;
222        emit Approval(msg.sender, _to, _pizzaId);
223    }
224
225    // 特定のピザの承認済みアドレスを返します
226    function getApproved(uint256 _pizzaId)
227        public
228        view
229        returns (address operator)
230    {
231        require(_exists(_pizzaId), "Pizza does not exist.");
232        return pizzaApprovals[_pizzaId];
233    }
234
235    /**
236     * 指定されたトークンIDの現在の承認をクリアするプライベート関数
237     * 指定されたアドレスがトークンのオーナーでない場合、取り消されます
238     */
239    function _clearApproval(address owner, uint256 _pizzaId) private {
240        require(pizzaToOwner[_pizzaId] == owner, "Must be pizza owner.");
241        require(_exists(_pizzaId), "Pizza does not exist.");
242        if (pizzaApprovals[_pizzaId] != address(0)) {
243            pizzaApprovals[_pizzaId] = address(0);
244        }
245    }
246
247    /*
248     * 指定されたオペレーターの承認を設定または解除します
249     * オペレーターは、送信者に代わってすべてのトークンを転送することが許可されます
250     */
251    function setApprovalForAll(address to, bool approved) public {
252        require(to != msg.sender, "Cannot approve own address");
253        operatorApprovals[msg.sender][to] = approved;
254        emit ApprovalForAll(msg.sender, to, approved);
255    }
256
257    // オペレーターが指定されたオーナーによって承認されているかどうかを通知します
258    function isApprovedForAll(address owner, address operator)
259        public
260        view
261        returns (bool)
262    {
263        return operatorApprovals[owner][operator];
264    }
265
266    // ピザの所有権を取得する - 承認されたユーザーのみ
267    function takeOwnership(uint256 _pizzaId) public {
268        require(_isApprovedOrOwner(msg.sender, _pizzaId), "Address is not approved.");
269        address owner = this.ownerOf(_pizzaId);
270        this.transferFrom(owner, msg.sender, _pizzaId);
271    }
272
273    // ピザが存在するかどうかを確認します
274    function _exists(uint256 pizzaId) internal view returns (bool) {
275        address owner = pizzaToOwner[pizzaId];
276        return owner != address(0);
277    }
278
279    // アドレスがオーナーであるか、ピザの転送が承認されているかを確認します
280    function _isApprovedOrOwner(address spender, uint256 pizzaId)
281        internal
282        view
283        returns (bool)
284    {
285        address owner = pizzaToOwner[pizzaId];
286        // 以下によるソリウムチェックの無効化
287        // https://github.com/duaraghav8/Solium/issues/175
288        // solium-disable-next-line operator-whitespace
289        return (spender == owner ||
290            this.getApproved(pizzaId) == spender ||
291            this.isApprovedForAll(owner, spender));
292    }
293
294    // ピザがユニークでまだ存在しないかを確認します
295    modifier isUnique(string memory _name, uint256 _dna) {
296        bool result = true;
297        for (uint256 i = 0; i < pizzas.length; i++) {
298            if (
299                keccak256(abi.encodePacked(pizzas[i].name)) ==
300                keccak256(abi.encodePacked(_name)) &&
301                pizzas[i].dna == _dna
302            ) {
303                result = false;
304            }
305        }
306        require(result, "Pizza with such name already exists.");
307        _;
308    }
309
310    // ターゲットアドレスがコントラクトであるかどうかを返します
311    function isContract(address account) internal view returns (bool) {
312        uint256 size;
313        // 現在、アドレスにコントラクトがあるかどうかを確認するのに、
314        // そのアドレスのコードのサイズを確認するより良い方法はありません。
315        // これがどのように機能するかについての詳細は、https://ethereum.stackexchange.com/a/14016/36603
316        // を参照してください。
317        // TODO Serenityリリースの前にこれを再確認してください。すべての
318        // アドレスがコントラクトになるためです。
319        // solium-disable-next-line security/no-inline-assembly
320        assembly {
321            size := extcodesize(account)
322        }
323        return size > 0;
324    }
325}
すべて表示
コピー